Error atau kesalahan dalam penulisan rumus adalah pasti dialami setiap pengguna Excel.
Fungsi ISERROR dalam Excel adalah fungsi yang bisa membantu kita melacak setiap error di worksheet.
Gunakan data pada file berikut untuk mempermudah teman-teman mengikuti demo-demo di artikel ini.
File: data-fungsi-iserror-excel.xlsx.
Apakah Fungsi ISERROR dalam Excel Itu?
Fungsi ISERROR adalah salah satu fungsi untuk menangkap error atau kesalahan di rumus Excel.
Fungsi ini bisa menangkap pesan error #CALC!, #DIV/0!, #N/A, #NAME?, #NUM!, #NULL!, #REF!, #VALUE!, dan #SPILL!.
Sintaks fungsi ISERROR di Excel adalah sebagai berikut:
=ISERROR(Nilai)
Nilai adalah nilai atau rumus yang ingin diperiksa apakah menghasilkan error atau tidak.
ISERROR akan mengembalikan TRUE bila rumus menghasilkan error. Bila tidak, ISERROR akan mengembalikan FALSE.
Cara Menggunakan Fungsi ISERROR Dalam Excel
Demo ini akan mengulang bagaimana menggunakan fungsi IFERROR seperti pada Gambar 01.
(Demo 01) Perhatikan langkah-langkah menggunakan fungsi ISERROR dalam Excel berikut.
- Pada cell D2, ketikkan
=ISERROR(. - Klik atau tuliskan cell
C2. Bagian ini adalah referensi yang mengarah pada rumus-rumus dan nilai-nilai di range C2:C12. - Ketikkan
)untuk mengakhiri rumus. - Tekan Enter untuk konfirmasi rumus.
- Salin rumus ke range D3:D12.
Penggunaan Rumus ISERROR dan IF
Bila berdiri sendiri, ISERROR tidak terlalu banyak berguna, terutama dari sisi pengguna informasi. Pengguna informasi pasti bingung apa itu TRUE dan FALSE. Sebagai pakar Excel, teman-teman perlu menerjemahkan kedua nilai tersebut menjadi bentuk yang lebih mudah dikenal.
Kita gunakan fungsi IF untuk menerjemahkan TRUE dan FALSE menjadi informasi yang lebih sesuai.
Pada demo kali ini, kita akan melihat rata-rata penjualan per unit setiap individu. Rata-rata didapatkan dengan membagi penjualan sebanyak jumlah unit yang dijual individu bersangkutan.
Tidak semua individu memiliki data jumlah.
(Demo 02) Berikut cara menggunakan fungsi ISERROR dalam Excel dengan IF.
- Pada cell D2, ketikkan
=IF(. - Lanjutkan dengan mengetikkan
ISERROR(B2/C2), tambahkan;. Pada rumus ini, fungsi ISERROR berperan sebagai obyek evaluasi fungsi IF untuk melihat apakah operasi B2/C2 menghasilkan error atau tidak. - Ketikkan
"Data jumlah belum diisi"dan;. Bagian ini akan dijalankan bila ISERROR bernilai TRUE. - Ketikkan
B2/C2. IF akan menjalankan perhitungan ini bila memang ISERROR bernilai FALSE, yang berarti tidak ada kesalahan di perhitungan. - Akhiri rumus dengan mengetikkan
)untuk menutup rumus IF. - Tekan Enter.
- Copy dan paste rumus D2 ke D3:D6.
Penggunaan Rumus Fungsi ISERROR dan VLOOKUP
VLOOKUP umumnya mengembalikan error #N/A karena nilai yang kita pakai tidak ada di tabel referensi.
Kita bisa menggunakan ISERROR untuk menangkap nilai error VLOOKUP.
(Demo 03) Berikut cara penggunaan rumus ISERROR dan VLOOKUP.
- Pada cell D2, ketikkan
=IF(. - Ketikkan
ISERROR(VLOOKUP(C2; $F$2:$G$3; 2; FALSE)), lanjutkan dengan pemisah daftar;. Bagian ini adalah di mana IF melakukan evaluasi terhadap VLOOKUP dengan fungsi ISERROR. - Ketikkan
"Cara bayar tidak ada"dan diikuti dengan pemisah;. Nilai teks ini akan ditampilkan bila VLOOKUP error, yang mengakibatkan ISERROR menghasilkan TRUE. - Ketikkan
VLOOKUP(C2; $F$2:$G$3; 2; FALSE)*B2. Rumus ini akan dijalankan bila ISERROR mengembalikan FALSE, yang berarti tidak ada kesalahan di penggunaan VLOOKUP. - Selesaikan rumus dengan tanda
). - Tekan Enter.
- Copy dan paste rumus D2 ke D3:D6.
Perhatian: Demo di atas adalah contoh. Fungsi VLOOKUP umumnya menghasilkan error #N/A. Untuk tipe error ini, sebaiknya gunakan fungsi yang lebih spesifik seperti IFNA atau ISNA.
Cara Menghitung Error di Excel dengan ISERROR
Pada akhirnya, ada orang-orang seperti kami yang sebenarnya gak terlalu suka pakai fungsi penangkap error seperti ISERROR.
Namun begitu, kami tetap perlu antisipasi error saat penggunaan rumus. Salah satu cara yang kami gunakan adalah menghitung jumlah error dan menampilkannya di satu cell tertentu.
Untuk tujuan ini, kami menggunakan operator unary.
Di Excel, operator unary dilambangkan dengan penggunaan dua tanda minus (–).
Operator ini akan mengubah nilai TRUE menjadi 1 dan FALSE menjadi 0.
Perhatikan rumus-rumus di bawah ini.
=--TRUE
=--ISERROR(8/0)
Masing-masing rumus di atas akan menghasilkan nilai 1.
Sementara itu, dua rumus di bawah ini akan menghasilkan nilai 0.
=--FALSE
=--NOT(ISERROR(NA()))
Kami menghapus perangkap error dari Demo 03 dan menampilkan error apa adanya.
(Demo 04) Berikut cara menghitung error di Excel dengan ISERROR.
- Pada cell D8, ketikkan
=SUM(. - Lanjutkan dengan mengetikkan operator unary terhadap ISERROR
--ISERROR(D2:D6). - Akhiri rumus dengan mengetikkan
)untuk menutup fungsi SUM. - Tekan Enter di keyboard.
Pada demo ini, operator unary akan mengubah hasil ISERROR menjadi 1 (bila TRUE) atau 0 (bila FALSE). Fungsi SUM lalu akan menjumlahkan angka-angka ini sebagai jumlah error yang terjadi.
Dengan cara ini, kami tau bahwa ada error di range bersangkutan.
Perhatikan kami menggunakan array D2:D6 sebagai parameter ISERROR.
Fungsi ISERR dan ISERROR
Excel memiliki fungsi lain serupa ISERROR, yaitu ISERR.
Perbedaannya, ISERR menangkap pesan-pesan kesalahan selain #N/A. Sementara itu, ISERROR akan menangkap semua bentuk pesan kesalahan, termasuk #N/A.
Kalau gitu, selain untuk #N/A, apakah ada perbedaan prinsip antara ISERROR dan ISERR?
Tidak ada.
Tapi, saran kami adalah gunakan fungsi sespesifik mungkin.
Kami pribadi menggunakan ISERR bila rumus yang kami gunakan punya resiko menghasilkan kesalahan selain #N/A. Bila ada kemungkinan #N/A, kami gunakan IFNA atau ISNA. Bila kami belum tahu sama sekali potensi kesalahan rumus, kami gunakan ISERROR.
Fungsi IFERROR dan ISERROR
Fungsi lain yang mirip dengan ISERROR adalah IFERROR.
Beda ISERROR dan IFERROR ada pada bentuk sintaks dan nilai kembalian. ISERROR hanya mengembalikan TRUE atau FALSE sebagai bentuk evaluasi nilai atau rumus. IFERROR mengembalikan nilai atau rumus yang dievaluasi bila hasil evaluasi FALSE atau nilai atau rumus alternatif bila hasil evaluasi TRUE (ada error)
IFERROR(Nilai; Nilai_Bila_Error)
Bisa dibilang IFERROR adalah kombinasi antara ISERROR dan fungsi IF.
Demo 03 menggunakan rumus di bawah ini:
=IF(ISERROR(VLOOKUP(C2; $F$2:$G$3; 2; FALSE)); "Cara bayar tidak ada"; VLOOKUP(C2; $F$2:$G$3; 2; FALSE)*B2)
Bila kita modifikasi rumus tersebut dengan fungsi IFERROR, maka akan menjadi seperti di bawah ini.
=IFERROR(VLOOKUP(C2; $F$2:$G$3; 2; FALSE)*B2; "Cara bayar tidak ada")
Pada beberapa kondisi, menggunakan IFERROR lebih baik dari pada kombinasi IF dan ISERROR. Namun, karena sifatnya lebih mendasar, IF dan ISERROR lebih fleksibel untuk kondisi-kondisi lainnya.
Penutup
Untuk mengamati hasil demo-demo di atas secara lebih jelas, buka file di bawah ini.
File: hasil-fungsi-iserror-excel.xlsx.
Terima kasih.