Dalam analisis data, sering kali kita perlu menemukan nilai terkecil berdasarkan kondisi tertentu—misalnya penjualan terendah di wilayah tertentu, atau tenggat paling awal untuk tugas prioritas tinggi. Fungsi MINIFS di Excel adalah solusi untuk kebutuhan ini.
Artikel ini membahas sintak MINIFS, kapan menggunakannya, tips praktis, contoh rumus, kesalahan umum, serta cara mengoptimalkan penggunaannya dalam skenario nyata.
File: fungsi-minifs-excel.xlsx
Apa itu Fungsi MINIFS di Excel?
Fungsi MINIFS adalah fungsi statistik yang mengembalikan nilai minimum dari suatu rentang yang memenuhi satu atau lebih kriteria.
Sintak
MINIFS(min_range; criteria_range1; criteria1; [criteria_range2; criteria2]; ...)
- min_range (wajib): rentang angka yang akan dicari nilai terkecilnya.
- criteria_range1 (wajib): rentang untuk kriteria pertama.
- criteria1 (wajib): kondisi yang harus dipenuhi bagi criteria_range1.
- criteria_range2, criteria2 (opsional): rentang dan kriteria tambahan.
Kapan Menggunakan Fungsi MINIFS?
Secara umum, gunakan MINIFS ketika kita perlu menemukan nilai minimum dengan filter tertentu.
Skenario umum:
- Menemukan penjualan terendah untuk produk tertentu di wilayah tertentu.
- Mengidentifikasi pengeluaran terkecil dalam kategori tertentu.
- Menentukan skor minimum di antara siswa yang lulus ujian.
- Menemukan tenggat paling awal untuk tugas prioritas tinggi.
Tips Menggunakan Rumus MINIFS
- Pastikan semua rentang (min_range dan criteria_range) memiliki ukuran sama.
- Gunakan kriteria yang jelas dan sederhana.
- MINIFS hanya berfungsi untuk data angka, termasuk tanggal dan waktu.
- MINIFS hanya tersedia di Excel 2016 ke atas.
- Periksa spasi tersembunyi atau format tidak konsisten pada data dan kriteria.
Contoh Rumus MINIFS di Excel
Menemukan Tanggal Pengiriman Tercepat dari Pemasok
Rumus di bawah adalah bentuk standar MINIFS. Rumus mengembalikan tanggal pengiriman terawal dari pemasok Petro Andalas.
=MINIFS(B2:B6; A2:A6; E1)Keterangan:
B2:B6(min_range) adalah rentang di mana nilai terkecil diambil.A2:A6(criteria_range1) adalah rentang kriteria.E1(criteria_1) adalah nilai yang akan dicari di criteria_range1.
Cocok untuk: Pelaporan logistik.
Nilai Terendah untuk Mata Pelajaran Tertentu
Rumus di bawah mengembalikan 93, yang merupakan nilai terendah dari mata pelajaran Matematika.
=MINIFS(C4:C9; A4:A9; F1)Cocok untuk: Rapor siswa.
Tenggat Terawal untuk Tugas Prioritas Tinggi
Rumus berikut mencari tanggal terawal dari tugas-tugas yang memiliki prioritas Tinggi.
=MINIFS(C2:C9; B2:B9; "Tinggi")Cocok untuk: Manajemen proyek.
Tanggal Kadaluwarsa Paling Dini
Rumus berikut mengembalikan tanggal kadaluwarsa terdekat untuk produk-produk dengan stok di atas nol.
=MINIFS(C2:C8; B2:B8; ">0")Cocok untuk: Keamanan pangan, inventaris bahan kimia, analisis logistik.
Penjualan Terendah di Wilayah Tertentu
Rumus MINIFS berikut menggunakan dua kriteria untuk mendapatkan penjualan terendah (C2:C9) sampai 31 Maret 2025 (A2:A9; "<="&A12) di wilayah Timur (B2:B9; B12).
=MINIFS(C2:C9; A2:A9; "<="&A12; B2:B9; B12)Cocok untuk: Analisis penjualan regional.
Proyek Berjalan dengan Tenaga Paling Sedikit
Rumus berikut menggunakan 2 kriteria untuk mencari proyek berjalan (D2:D9; B12) dengan manajer Nelly (A2:A9; A12) yang memiliki jumlah anggota tim terendah (C2:C9).
=MINIFS(C2:C9; A2:A9; A12; D2:D9; B12)Cocok untuk: Manajemen proyek.
Proyek dengan Tenaga Paling Sedikit & Tenggat Terawal
Rumus berikut menggabungkan IF dan MINIFS dengan 3 kriteria untuk mendapatkan proyek dengan:
- Tenggat terdekat sejauh-jauhnya 30 hari ke depan (
C4:C11; "<"&TODAY()+30) - Proyek masih berjalan (
D4:D11; "Progres") - Anggota tim tidak mencapai 5 orang (
B4:B11; "<5")
=IF(MINIFS(C4:C11; C4:C11; "<"&TODAY()+30; D4:D11; "Progres"; B4:B11; "<5")>0; "Ada"; "Tidak")Cocok untuk: Manajemen proyek.
Harga Terbaik untuk Produk Tertentu
Rumus berikut menggunakan wildcard untuk mencari harga terendah dari produk botol air minum dari berbagai merek (A2:A11; "*water bottle*").
Cocok untuk: Analisa harga.
=MINIFS(B2:B11; A2:A11; "*water bottle*")
Kesalahan Umum Rumus MINIFS dan Solusinya
| Masalah | Penyebab | Solusi |
|---|---|---|
| Error #VALUE! | Rentang-rentang berbeda ukuran | Semua rentang harus sama ukuran |
| Error #NAME? | MINIFS tidak dikenali | Gunakan Excel 2016 atau lebih baru |
| Hasil tidak akurat | Spasi tersembunyi atau format tidak konsisten | Periksa kriteria atau konsistensi format data |
| Hasil nol | Tidak ada nilai memenuhi kriteria | Pastikan kriteria benar dan ada data yang cocok |
Perbandingan MIN dan MINIFS
| Fitur | MIN | MINIFS |
|---|---|---|
| Logika | Menemukan angka terkecil dalam suatu rentang | Menemukan angka terendah yang memenuhi aturan tertentu |
| Penanganan nol | Termasuk angka nol (seringkali menghasilkan 0). | Angka nol dapat dikecualikan dengan kriteria “0” |
| Dukungan tanggal | Menemukan tanggal terawal dalam keseluruhan daftar | Menemukan tanggal terawal untuk kategori tertentu |
Kesimpulan
Fungsi MINIFS adalah alat bermanfaat untuk analisis terarah di Excel. Dengan memahami sintak, praktik terbaik, dan kesalahan umum, pengguna dapat secara efisien mengambil nilai minimum yang memenuhi kondisi tertentu. Dengan contoh dan tips di atas, kami harap teman-teman siap untuk menerapkan MINIFS ke skenario data dan meningkatkan keputusan berbasis data.