Dalam banyak sistem bisnis di Indonesia—mulai dari manufaktur, logistik, e‑commerce, hingga IT—informasi penting sering ditempatkan di bagian akhir sebuah kode. Digit terakhir bisa menentukan batch produksi, varian rilis, tingkat keanggotaan, kode cabang, atau bahkan format file.
Di sinilah fungsi RIGHT menjadi penting. RIGHT bukan sekadar “mengambil karakter dari kanan,” tapi juga untuk:
- decoding SKU
- membaca struktur kode manufaktur
- memetakan batch dan tanggal kadaluwarsa
- memproses ekstensi file
- mengekstrak segmen URL
- mengelola ID pelanggan dan nomor kartu
Artikel ini membahas RIGHT dari perspektif analisis kode modern, selain sebagai fungsi teks dasar.
File: fungsi-right-excel.xlsx
Apa Itu Fungsi RIGHT di Excel?
RIGHT digunakan untuk mengambil sejumlah karakter tertentu dari sisi kanan sebuah teks.
Fungsi ini cocok digunakan untuk teks yang suffix-based, atau berbasis akhiran.
Sintaksis
RIGHT(text; [num_chars])
- text (wajib): Teks atau referensi cell dengan teks yang ingin diambil karakternya.
- num_chars (opsional): Jumlah karakter yang ingin diambil dari kanan. Jika dikosongkan, Excel akan mengambil satu karakter terakhir secara default.
Kapan Menggunakan Fungsi RIGHT?
Gunakan RIGHT ketika informasi yang kita butuhkan berada di bagian akhir teks, seperti, tapi tidak eksklusif pada:
- kode cabang dari nomor faktur
- digit verifikasi dari nomor kartu atau ID pelanggan
- kode warna dari SKU produk
- variasi rilis dari kode SKU manufaktur
- nomor batch dari kode produksi
- ekstensi file dari nama file
- segmen terakhir URL untuk analisis SEO
- dua digit terakhir tahun dari tanggal dalam format teks
RIGHT berguna dalam:
- otomatisasi laporan
- pemetaan kode ke kategori
- validasi data
- analisis SKU dan inventori
- pembersihan data impor
Tips Menggunakan Rumus RIGHT
- Gunakan RIGHT jika pola kode konsisten di bagian akhir teks
- Jika panjang karakter bervariasi, gunakan LEN atau FIND
- Untuk pemisah terakhir (spasi, slash, titik), gunakan SUBSTITUTE
- Hasil RIGHT selalu berupa teks. Gunakan VALUE jika hasil diinginkan untuk diolah dalam suatu perhitungan
- Untuk data impor, bersihkan dulu dengan TRIM atau CLEAN
Contoh Rumus RIGHT di Excel
Mengambil Nomor Versi dari Nama Produk
Suatu perusahaan ingin mengambil versi dari suatu produk yang tersemat pada kode produk internal untuk identifikasi generasi produk saat forecasting. Versi produk adalah 7 karakter terakhir dari kode tersebut.
=RIGHT(A2; 7)
Mengambil Kode Warna dari Varian Produk
Suatu departemen di suatu perusahaan ingin mengambil varian warna yang ada di kode produk internal untuk perencanaan persediaan. Kode warna adalah 3 karakter terakhir dari kode produk internal.
=RIGHT(A2; 3)
Mendeteksi Format File dari Nama File
Departemen IT mendata ekstensi atau format file attachment dari suatu karyawan untuk melihat kebutuhan karyawan tersebut untuk aplikasi tertentu.
Rumus menggunakan kombinasi dengan FIND untuk antisipasi format file yang bisa terdiri dari 3 atau 4 karakter.
=RIGHT(A2; LEN(A2)-FIND("."; A2))
Menentukan Keanggotaan dari Digit Terakhir Kartu Loyalitas
Sebuah restoran memberikan loyalty card kepada pelanggan yang mendaftar. Loyalty card memiliki 16 digit nomor identitas. 4 digit terakhir adalah tingkat keanggotaan dari pelanggan. Manajemen restoran ingin melihat keanggotaan berdasarkan 4 digit tersebut.
=XLOOKUP(RIGHT(A2; 4); $D$2:$D$5; $E$2:$E$5)
Menentukan Edisi Suatu Produk
Suatu vendor mainan memiliki serangkaian kode SKU di mana 2 digit terakhir kode adalah variasi rilis. Vendor ingin mengetahui deskripsi setiap produk berdasarkan kode variasi rilis lewat kombinasi dengan SWITCH.
=SWITCH(RIGHT(A2; 2); "CO"; "Collectible"; "SP"; "Special Edition"; "LE"; "Limited Edition"; "Standard")
Mengambil Nama Belakang dari Nama Lengkap
Suatu perusahaan menempatkan nama belakang terlebih dahulu untuk pelaporan kinerja bulanan.
Rumus menggunakan kombinasi dengan LEN, FIND, dan SUBSTITUTE untuk mengambil nama belakang terlepas dari jumlah kata di dalam nama.
=RIGHT(A2; LEN(A2) - FIND("@"; SUBSTITUTE(A2; " "; "@"; LEN(A2) - LEN(SUBSTITUTE(A2; " "; "")))))
Mengambil Segmen Terakhir dari URL
Sebuah perusahaan ingin mengambil segmen terakhir dari serangkaian tautan untuk tujuan analisis SEO dan pemetaan konten.
Rumus menggunakan kombinasi dengan LEN, FIND, dan SUBSTITUTE untuk mendapatkan posisi tanda slash terakhir sebagai pemandu lokasi segmen terakhir.
=RIGHT(A2; LEN(A2) - FIND("@"; SUBSTITUTE(A2; "/"; "@"; LEN(A2) - LEN(SUBSTITUTE(A2; "/"; "")))))
Mengambil Nomor Batch dari Kode Manufakturing
Seorang manajer gudang mengambil nomor batch, yaitu 5 digit terakhir dari kode manufakturing, untuk menentukan produk-produk mana saja yang akan kadaluwarsa dalam 3 bulan.
Rumus menggunakan kombinasi dengan IF dan XLOOKUP untuk melihat data di tabel batch.
=IF(XLOOKUP(RIGHT(A5;5); $D$5:$D$9; $E$5:$E$9)-EDATE($B$1; B$2)<=0; "Ya"; "Tidak")
Kesalahan Umum Rumus RIGHT dan Solusinya
| Kesalahan | Penyebab | Solusi |
| Error #VALUE! | num_chars negatif atau bukan angka | Gunakan angka bulat positif |
| Hasil tidak sesuai | num_chars tidak cocok dengan pola data | Gunakan LEN untuk menghitung panjang teks |
| Nol di depan data sumber hilang | Data dianggap angka, bukan teks | Ubah format cell menjadi teks sebelum menempatkan data di cell tersebut |
| Error #NAME? | Salah ketik nama fungsi | Periksa ejaan RIGHT |
| Hasil tidak rata kiri | Ada spasi sebelum hasil | Sesuaikan argumen char_num atau gunakan TRIM |
Kesimpulan
Fungsi RIGHT adalah alat penting dalam pengolahan teks di Excel. Dengan memahami pola umum, menggabungkannya dengan fungsi lain, dan menerapkan contoh dunia nyata, kita dapat memanfaatkan RIGHT untuk mempercepat pekerjaan, membersihkan data, dan mengotomatisasi analisis kode.
RIGHT bukan hanya fungsi sederhana, tapi juga dasar untuk alur kerja modern di logistik, e‑commerce, manufaktur, HR, dan data cleaning.