Rumus RANDARRAY: Cara Membuat Tabel Angka di Excel

Fungsi RAND dan RANDBETWEEN baik untuk membuat satu angka secara acak. Namun, untuk dua angka acak atau lebih, fungsi RANDARRAY adalah cara yang lebih baik.

Artikel ini mengurai rumus RANDARRAY di Excel.

File: fungsi-randarray-excel.xlsx.

Apa Itu Fungsi RANDARRAY Excel?

Fungsi RANDARRAY pada Excel adalah fungsi yang menghasilkan satu atau lebih angka acak di antara dua angka.

Hasil kembalian rumus RANDARRAY berupa array atau tabel angka.

Agar lebih paham penggunaan RANDARRAY, kami sarankan agar teman-teman mengerti terlebih dahulu konsep dasar array di Excel.

Sintaks

RANDARRAY([rows]; [columns]; [min]; [max]; [whole_number])

Berikut keterangan masing-masing parameter:

• rows (opsional) adalah jumlah baris yang akan dikembalikan di dalam tabel.
  • Bila tidak dituliskan nilai default rows adalah 1.
• columns (opsional) adalah jumlah kolom yang akan dikembalikan di dalam tabel
  • Bila tidak dituliskan nilai default parameter ini adalah 1.
• min (opsional) adalah batas bawah atau angka terkecil yang mungkin dikembalikan.
  • Bila tidak dituliskan, min bernilai 0.
• max (opsional) adalah angka terbesar yang ingin dikembalikan.
  • Saat tidak disertakan, max bernilai 1.
• integer (opsional) adalah nilai logika untuk menentukan apakah RANDARRAY mengembalikan bilangan bulat atau desimal.
  • TRUE: hasil berupa bilangan bulat.
  • FALSE (atau bila tidak dituliskan): hasil berupa angka desimal.

Mengenai Rumus RANDARRAY

• Bila kita tidak memberikan parameter apa pun, RANDARRAY akan mengembalikan satu angka desimal di antara nol dan satu.
• min harus lebih kecil dari max. Bila tidak nilai error #VALUE! akan tampil.
• Hasil rumus RANDARRAY adalah array. Sebab itu, hasilnya akan tertumpah ke cell-cell di sekitarnya. Pastikan tidak ada nilai di cell-cell sepanjang min-1 ke bawah dan max-1 dari cell di mana rumus ditulis. Bila tidak, pesan error #SPILL! muncul.
• Hasil rumus RANDARRAY akan terus berubah setiap kali workbook dibuka atau ada perubahan. Semakin banyak rumus di dalam workbook, semakin lambat kerja Excel.

Cara Menggunakan Rumus RANDARRAY Excel

Seperti teman-teman perhatikan sintaksnya, fungsi RANDARRAY tidak memiliki parameter wajib. Dengan demikian, rumus paling sederhana di Excel hanya mengikutkan nama fungsi.

=RANDARRAY()

Rumus di atas akan mengembalikan satu angka acak di antara nol dan satu.

Angka Acak di Antara Dua Angka

Seperti RANDBETWEEN, fungsi RANDARRAY mampu mengembalikan angka acak di antara dua angka. Caranya adalah dengan menentukan batas bawah (parameter min) dan batas atas (parameter max).

Rumus di bawah akan mengembalikan daftar angka-angka desimal dari lima sampai lima belas.

=RANDARRAY(;;5;15)

Agar rumus mengembalikan angka bulat, tetapkan nilai parameter integer menjadi TRUE.

=RANDARRAY(;;5;15; TRUE)

Cara Membuat Tabel Angka di Excel

Kekuatan RANDARRAY sesungguhnya terletak pada kemampuannya untuk menghasilkan beberapa angka acak sekaligus.

Tabel Angka Satu Kolom

Tabel angka satu kolom dibuat dengan memberikan nilai bagi rows untuk menentukan jumlah baris yang diinginkan.

Rumus di bawah mengembalikan tabel angka desimal sebanyak lima baris.

=RANDARRAY(5)

Tabel Angka Satu Baris

Dengan memberikan angka di atas satu bagi columns, rumus RANDARRAY akan mengembalikan tabel angka acak yang terdiri dari beberapa baris.

Rumus di bawah akan menampilkan sebaris array yang terdiri dari empat kolom.

=RANDARRAY(; 4)

Tabel Angka Beberapa Kolom dan Baris

Tabel dengan beberapa baris dan kolom memiliki nilai-nilai rows dan columns masing-masing di atas satu.

Rumus berikut mengembalikan tabel angka yang terdiri dari lima baris dan tiga kolom.

=RANDARRAY(5; 3)

Agar rumus mengembalikan tabel yang terdiri dari hanya angka bulat dengan fungsi RANDARRAY, lakukan hal-hal berikut:

• Tentukan tinggi dan lebar tabel dengan rows dan columns.
• Tentukan batas bawah dengan min.
• Tentukan batas atas dengan max.
• Berikan nilai TRUE bagi integer.

Tanpa nilai min dan max, RANDARRAY akan mengembalikan hanya 1 atau 0.

Rumus di bawah akan mengembalikan angka bulat acak dari satu sampai tiga puluh di dalam tabel yang terdiri dari lima baris dan tiga kolom.

=RANDARRAY(5; 3; 1; 30; TRUE)

Cara Membuat Jam Acak di Excel

Tahukah teman-teman bahwa waktu di Excel sebenarnya adalah angka desimal dari nol sampai satu? Secara default, fungsi RANDARRAY mengembalikan angka desimal dari nol sampai satu.

=RANDARRAY(10; 1; B1; B2)

Rumus di atas akan menghasilkan satu kolom dengan sepuluh waktu acak mulai dari jam 09:00 sampai 17:00. Bila kembalian dalam bentuk desimal, gunakan format Time untuk memformat angka-angka tersebut sebagai waktu.

Mengelompokkan Orang-orang

Ingin memecah sekelompok orang ke dalam satu atau beberapa kelompok? Rumus RANDARRAY dapat membantu.

=SORTBY(A2:A11; RANDARRAY(COUNTA(A2:A11)))

Berikut penjelasan rumus.

Hasilnya bisa dilihat pada gambar di bawah.

Cara Membuat Undian Angka Acak

Bagaimana cara membuat undian dengan angka acak?

Biasanya undian memiliki nomor unik. Nomor ini kemudian dipilih sebagai pemenang hadiah tertentu.

Katakan ada seribu peserta, masing-masing memiliki nomor undian. Nomor ini terentang dari satu sampai seribu. Sepuluh pemenang dipilih secara acak dan nomor yang sama tidak boleh keluar dua kali.

Dengan memodifikasi rumus mengelompokkan orang, kita mendapatkan rumus terlampir di bawah.

=INDEX(SORTBY(SEQUENCE(1000); RANDARRAY(1000)); SEQUENCE(10))

Rumus mencari sepuluh angka unik secara acak di dalam rentang satu sampai seribu.

Memilih Nama Secara Acak

Bila teman-teman mau, rumus pada bagian sebelumnya bisa dimodifikasi kembali untuk mengambil beberapa nama dari sekumpulan nama.

Cara ini juga bisa dipakai untuk memilih pemenang undian, pengemban tugas piket, dan lain sebagainya.

=INDEX(SORTBY(A2:A11; RANDARRAY(ROWS(A2:A11))); SEQUENCE(3))

Rumus mengurutkan data A2:A11 berdasarkan array yang diperoleh dari RANDARRAY(ROWS(A2:A11)). INDEX kemudian mengambil tiga nama dari A2:A11.