Rumus RANDBETWEEN: Cara Membuat Angka Acak di Excel

Artikel ini mengurai Rumus RANDBETWEEN Excel serta beberapa contoh penggunaannya.

Daftar Isi

Apa Itu Fungsi RANDBETWEEN pada Excel?

Fungsi RANDBETWEEN Excel adalah fungsi untuk menghasilkan angka acak atau random di antara dua angka.

Sintaks

RANDBETWEEN(bottom; top)

bottom (wajib) adalah batas bawah atau angka terkecil yang mungkin dari angka acak yang dicari.
top (wajib) adalah batas atas atau angka terbesar yang mungkin dari angka acak yang dicari.

Mengenai Rumus RANDBETWEEN

Pesan #NUM!.
Pesan ini tampil saat bottom lebih besar dari pada top.
Pesan #VALUE!.
Pesan ini terjadi saat bottom atau top bukan angka.
Performa.
Rumus RANDBETWEEN dihitung ulang setiap kali file dibuka atau terjadi perubahan. Semakin banyak rumus ini, semakin banyak perhitungan ulang yang terjadi dan semakin berat Excel.
Antisipasinya, gunakan RANDBETWEEN dengan rentang angka sekecil mungkin atau kurangi rumus sebisa mungkin.

Kapan Menggunakan Rumus RANDBETWEEN Excel

Membuat data contoh. Data contoh berguna untuk menguji rumus atau analisa statistik. Kalau kami boleh jujur, hampir semua data angka di website ini adalah hasil RANDBETWEEN.
Simulasi data. Data pasar biasanya bersifat acak. RANDBETWEEN membantu kita memberikan hasil dengan fluktuasi seperti yang terjadi di pasar. Contoh: penjualan untuk tiap bulan.
Membagi kelompok. Kita dapat menggunakan fungsi ini agar memberikan nama secara acak bagi kelompok tertentu.
Memilih pemenang dari daftar peserta.
Membuat games, kuis, atau permainan lainmya yang membutuhkan sifat keacakan seperti memilih pertanyaan.

Cara Membuat Angka Acak di Excel

Cara membuat angka acak di Excel dengan fungsi RANDBETWEEN dilakukan dengan memasukkan angka batas bawah dan atas sebagai parameter dengan pemisah daftar di antara keduanya.

Pada rumus di bawah, rumus akan menghasilkan angka sekecil-kecilnya 101 dan sebesar-besarnya 1000.

=RANDBETWEEN(101; 1000)

Selain bilangan positif, RANDBETWEEN juga menerima bilangan negatif.

Rumus di bawah mencari angka acak di antara -50 dan 50.

=RANDBETWEEN(-50; 50)

Bila menggunakan referensi, maka rumus tampak seperti berikut.

=RANDBETWEEN(A2; B2)

Pastikan angka yang lebih kecil sebagai bottom untuk menghindari pesan error #NUM!.

Cara Membuat Angka Acak Desimal

Walau pun angka yang dihasilkan oleh RANDBETWEEN adalah bulat secara default, kita dapat membuat fungsi ini mengembalikan bentuk desimal.

Sintaks

RANDBETWEEN(bottom*10^n; top*10^n)/ 10^n

n adalah jumlah tempat desimal yang diinginkan.

Sebagai contoh bila angka acak yang diinginkan memiliki satu tempat desimal, maka 10¹ = 10. Bila dua, maka 10²100. Bila tiga, maka 1000, demikian seterusnya.

Rumus-rumus di bawah akan mengembalikan angka acak di antara 101 dan 1000 dengan dua tempat desimal.

=RANDBETWEEN(A2*10^2; B2*10^2)/10^2

=RANDBETWEEN(A2*100; B2*100)/100

Gambar 02. RANDBETWEEN mengembalikan angka desimal.

Bila jumlah tempat desimal tidak tampil seperti yang kita inginkan, gunakan perintah Increase Decimal atau Decrease Decimal.

Cara Memilih Nama Acak di Excel

Memilih nama secara acak punya banyak kegunaan dan Excel ada banyak cara untuk itu.

Salah satunya adalah menggunakan fungsi CHOOSE.

Rumus di bawah memilih salah satu dari lima nama di dalam daftar berdasarkan angka yang dikembalikan RANDBETWEEN.

=CHOOSE(RANDBETWEEN(1; 5); "Eko"; "Novi"; "Rendi"; "Petrus"; "Daniel")

Kelemahan rumus di atas adalah semakin banyak nama, semakin panjang daftar.

Cara lain adalah dengan menuliskan daftar nama di worksheet dan memberikan angka berurut kepada setiap nama. Angka kembalian RANDBETWEEN berperan sebagai indeks lookup untuk setiap nama. Dari sini, gunakan VLOOKUP, XLOOKUP, INDEX, INDIRECT, atau fungsi lookup lainnya untuk mencari angka tersebut di dalam daftar.

=VLOOKUP(RANDBETWEEN(1; 5); A2:B6; FALSE)

=INDEX(B2:B6; RANDBETWEEN(1; 5); 1)

Cara favorit kami adalah menggunakan fungsi INDIRECT.

=INDIRECT("B"&RANDBETWEEN(2; 6))

Gambar 03. Memilih nama secara acak di Excel.

Cara Membuat Tanggal Acak di Excel

Membuat tanggal secara acak punya banyak variasi, tergantung kebutuhan kita.

Untuk tanggal acak pada tahun tertentu, rumus dapat dibuat seperti di bawah ini.

=DATE(2024; 1; RANDBETWEEN(1; 366))

Untuk tanggal acak dalam rentang tahun-tahun tertentu, gunakan rumus berikut.

=DATE(RANDBETWEEN(1990; 2024); 1; RANDBETWEEN(1; 366))

Pada rumus-rumus di atas, DATE akan menyesuaikan bulan berdasarkan jumlah hari. Sebagai contoh, bila tahun adalah 2024, bulan adalah 1, dan hari adalah 32, maka rumus mengembalikan 1 Februari 2024.

Cara Membuat Huruf Acak di Excel

Untuk membuat RANDBETWEEN mengembalikan huruf secara acak, kita perlu tahu rentang kode ASCII dari huruf-huruf yang diinginkan.

Sebagai contoh, huruf A memiliki kode ASCII 65, B adalah 66, C adalah 67, dan seterusnya sampai Z dengan kode 90.

Dengan demikian, rumus RANDBETWEEN yang diperlukan adalah rumus dengan rentang 65 sampai 90.

=RANDBETWEEN(65; 90)

Excel memiliki fungsi bernama CHAR yang mengubah kode ASCII menjadi nilai yang dikandung kode tersebut. Dengan menambahkan fungsi tersebut terhadap RANDBETWEEN, kita mendapatkan rumus membuat huruf acak di Excel.

=CHAR(RANDBETWEEN(65; 90))

Tentu saja tidak semua orang hapal isi tabel ASCII, tidak juga kami. Cara lain adalah menggunakan fungsi CODE. Fungsi ini mengubah suatu karakter, termasuk huruf, menjadi kode ASCII.

=CHAR(RANDBETWEEN(CODE("A"); CODE("Z")))

Di dalam tabel ASCII, huruf A dan a memiliki kode yang berbeda. Agar RANDBETWEEN mengembalikan huruf kecil secara acak ganti huruf-huruf kapital dengan huruf kecil.

=CHAR(RANDBETWEEN(CODE("a"); CODE("z")))

Bila karena suatu sebab teman-teman menginginkan huruf kecil atau huruf besar dikembalikan oleh rumus yang sama, coba rumus berikut.

=CHAR(CHOOSE(RANDBETWEEN(1;2);RANDBETWEEN(CODE("A");CODE("Z"));RANDBETWEEN(CODE("a");CODE("z"))))

Cara lainnya adalah dengan mendaftarkan semua huruf di dalam suatu kolom dan memberikan angka unik bagi huruf-huruf tersebut, seperti yang kita lakukan saat memilih nama secara acak.

Tips: Bila teman-teman berniat menampilkan karakter-karakter istimewa, karakter-karakter ini memiliki kode ASCII 33 sampai 47.

Cara Membuat Password di Excel

Membuat password pada dasarnya adalah membuat teks dengan karakter-karakter yang dipilih secara acak.

Seperti kasus-kasus lainnya, ada beberapa cara membuat password atau teks acak di Excel dengan rumus RANDBETWEEN.

Pada contoh ini, kami menggunakan fungsi INDEX.

Berikut caranya :

Pada kolom A, buat daftar huruf besar dari A sampai Z.
Pada kolom B, buat daftar huruf a sampai z.
Pada kolom C, buat daftar karakter istimewa. Berhubung jumlahnya tidak sampai 26, teman-teman bisa isi cell-cell di bawahnya dengan karakter-karakter istimewa yang sudah ada.
Pada kolom D, buat daftar angka. Seperti karakter istimewa, isi cell-cell di bawahnya dengan angka-angka yang sudah ada.
Pada cell F1, tuliskan rumus berikut =INDEX(A2:D27; RANDBETWEEN(1; 26); RANDBETWEEN(1; 4)).
1. A2:D27 adalah tabel karakter.
2. RANDBETWEEN(1; 26) memilih posisi baris secara acak.
3. RANDBETWEEN(1; 4) memilih posisi kolom secara acak.
4. Fungsi INDEX akan mengembalikan karakter berdasarkan posisi baris dan kolom kembalian RANDBETWEEN.
Salinkan rumus F1 ke cell-cell di bawahnya. Banyaknya salinan tergantung pada seberapa panjang password atau teks yang dibutuhkan. Bila sepuluh karakter, maka salinkan rumus sampai ke F10.
Pada cell H2 (atau di mana pun kecuali kolom F. Tahu kenapa?), tulis rumus =CONCAT(F:F).

Perhatikan hasilnya pada gambar berikut.

Gambar 06. Membuat password di Excel dengan RANDBETWEEN.

Hasil Rumus RANDBETWEEN Tidak Berubah

Saat terjadi perubahaan di workbook, hasil rumus RANDBETWEEN juga berubah. Bila karena suatu sebab teman-teman menerima angka acak yang dihasilkan rumus ini dan tidak mau berubah lagi, salin hasil rumus dan gunakan Paste Special Values.

Contoh-contoh Lain Rumus RANDBETWEEN

Dengan teknik yang tepat, fungsi RANDBETWEEN dan RAND dapat digunakan sebagai alternatif satu sama lain. karena itu, kami juga menyarankan agar teman-teman juga membaca mengenai fungsi RAND.

Baca: Fungsi RAND Excel.