Lompat ke konten
Home » Blog » Fungsi SUMSQ Excel: Cara Menghitung Jumlah Kuadrat

Fungsi SUMSQ Excel: Cara Menghitung Jumlah Kuadrat

Share :

Salah satu fungsi Excel yang sering diabaikan tetapi memiliki manfaat besar adalah SUMSQ. Fungsi ini ideal untuk berbagai kebutuhan, mulai dari statistik hingga geometri.

Artikel ini akan membahas cara kerja fungsi SUMSQ, penggunaannya, serta contoh-contoh praktis yang kami harap dapat membantu teman-teman memanfaatkan potensi penuh fungsi ini.

Gunakan file berikut untuk untuk membantu memahami rumus-rumus di tulisan ini.

File: fungsi-sumsq-excel.xlsx.

Apa Itu Fungsi SUMSQ di Excel?

Fungsi SUMSQ di Excel digunakan untuk menjumlahkan nilai pangkat dua dari sederetan angka. Sebagai contoh:

  • =SUMSQ(1; 2) akan menghasilkan 5 karena 12+22=5.
Sintaks

SUMSQ(number1; [number2]; …)
  • number1 (wajib) adalah angka pertama yang dikuadratkan dan dijumlahkan.
  • number2–number255 (opsional) adalah angka kedua hingga angka ke-255 yang juga dikuadratkan, lalu dijumlahkan.

SUMSQ juga mendukung parameter berupa range dan array.

Cara Menggunakan Fungsi SUMSQ di Excel

Misalkan kita memiliki angka 2, 3, dan 4.

  • Untuk menggunakan nilai langsung, gunakan rumus berikut:
    =SUMSQ(2; 3; 4)
  • Dalam bentuk array, gunakan rumus seperti di bawah ini:
    =SUMSQ({2; 3; 4})
  • Untuk menggunakan range, tempatkan angka-angka di sel (contoh: A2, B2, dan C2), lalu gunakan rumus:
    =SUMSQ(A2:C2)

Rumus mengembalikan 29.

Tips: Periksa hasil rumus dengan menggunakan SUM: =SUM(2^2; 3^2; 4^2) atau =SUM(A2:C2^2).

Menggunakan Rumus SUMSQ dengan Beberapa Range

Untuk data yang tersebar dalam beberapa range (contoh: A2:C2 dan A5:C5), gunakan rumus berikut:

=SUMSQ(A2:C2; A5:C5)

Berdasarkan data pada gambar, rumus mengembalikan nilai 91.

Menghitung Rumus Phytagoras di Excel

Sintaks

c2 = a2 + b2

Di mana:

  • a dan b adalah sisi tegak.
  • c adalah hipotenusa atau garis miring.

Di Excel, rumus phytagoras dapat dihitung dengan mengkombinasikan SUMSQ dan SQRT.

Jika sisi tegak segitiga adalah 3 dan 4 cm, maka rumus adalah:

=SQRT(SUMSQ(A2:B2))

Cara Menghitung Varian dengan SUMSQ

Varian mengukur seberapa jauh data individual berbeda dari rata-rata.

Varian Populasi:

  • σ² = Σ (xi - μ)² / n

Varian Sampel:

  • s² = Σ (xi - x̄)² / (n - 1)

Di mana:

  • xi: data individual.
  • μ: rata-rata populasi.
  • x̄: rata-rata sampel.
  • n: banyaknya data dalam populasi.

Kami menggunakan data berikut: 6, 5, 8, 3, 8. Berdasarkan data tersebut, maka rumus adalah sebagai berikut:

=SUMSQ(B2:B6-AVERAGE(B2:B6))/COUNT(B2:B6)

Berikut langkah-langkah penjelasannya.

Langkah Perhitungan Hasil Rumus Excel
1.      Hitung banyak data. 5 =COUNT(B2:B6)
2.      Hitung rata-rata data. (6+5+8+3+8)/5=6

 

 =AVERAGE(B2:B6)
3.      Hitung simpangan setiap angka.
  • 6-6=0
  • 5-6=-1
  • 8-6=2
  • 3-6=-3
  • 8-6=2
 =SUMSQ(B2:B6-AVERAGE(B2:B6))
4.      Pangkatkan simpangan.
  • 02=0
  • -12=1
  • 22=4
  • -32=9
  • 22=4
5.      Jumlahkan hasil pangkat 0+1+4+9+4=18
6.      Bagi jumlah hasil pangkat dengan banyak data. 18/5=3,60 =SUMSQ(B2:B6-AVERAGE(B2:B6))/ COUNT(B2:B6)

Untuk varian sampel, kurangi banyaknya data dengan satu.

=SUMSQ(B2:B6-AVERAGE(B2:B6))/(COUNT(B2:B6)-1)

Catatan: Untuk Excel 2019 dan ke bawah, gunakan Ctrl+Shift+Enter, alih-alih Enter, untuk menjalankan rumus.

Menggabungkan SUMSQ dengan Fungsi IF Excel

Bila komponen data varian memiliki nilai-nilai tertentu yang ingin dihitung atau diabaikan, kombinasikan SUMSQ dengan IF.

Contoh data: 6, 0, 5, 0, 8, 3, 8. Dengan mengabaikan nilai 0, maka rumus adalah:

=SUMSQ(IF(B2:B8>0; B2:B8-AVERAGEIF(B2:B8; ">0")))/(COUNTIF(B2:B8; ">0")-1)

Hasilnya tetap 3,60.

Langkah-langkah perhitungan tetap sama dengan sebelumnya. Perbedaannya terletak pada penggunaan fungsi yang lebih sesuai: COUNT menjadi COUNTIF dan AVERAGE menjadi AVERAGEIF.

Secara khusus, IF(B2:B8>0; B2:B8-AVERAGEIF(B2:B8; ">0")) mengambil nilai individu yang lebih besar dari nol.

Cara Menghitung Standar Deviasi dengan SUMSQ

Standar deviasi adalah akar dari varian.

  • Populasi: 
    σ = √(Σ (xi - μ)² / n)
  • Sampel: 
    s = √(Σ (xi - x̄)² / (n - 1))

Dengan mengambil contoh yang sudah ada, maka rumus adalah:

=SQRT(SUMSQ((B2:B6)-AVERAGE(B2:B6))/COUNT(B2:B6))

Mengapa Rumus SUMSQ Tidak Bekerja

  • Penggunaan teks sebagai parameter (#VALUE!).
    • Contoh: =SUMSQ("Tiga"; "Empat").
  • Data terlalu besar.
    • Contoh: =SUMSQ(SEQUENCE(10000; 10000)).
  • Referensi range salah atau file eksternal tidak terbuka.
  • Array pada Excel 2019 ke bawah tidak dieksekusi dengan Ctrl+Shift+Enter.