Rumus TRANSPOSE Excel

Salah satu cara memahami data adalah dengan mengubah sudut pandangnya. Contohnya, bila data terentang secara horisontal, kita dapat mengubahnya menjadi vertikal, atau sebaliknya.

Kita dapat menggunakan rumus TRANSPOSE Excel untuk tujuan tersebut, seperti yang akan kita bahas di artikel ini.

File: fungsi-transpose-excel.xlsx.

Apa Itu Rumus TRANSPOSE Excel?

Fungsi TRANSPOSE Excel adalah fungsi yang mengubah orientasi data dari vertikal menjadi horisontal dan sebaliknya.

Sintaks

TRANSPOSE(array)

• array adalah array atau range data yang akan diubah orientasinya.
  • array tidak boleh berupa cell atau range yang tidak berdekatan.

Fungsi TRANSPOSE mengembalikan data berupa array. Format apa pun yang dimiliki data sumber tidak akan disertakan.

Karena berupa array, pastikan tidak ada cell terisi pada range di mana hasil array tertumpah. Jika tidak, maka pesan error #SPILL! tampil.

Menggunakan fungsi TRANSPOSE memerlukan pemahaman dasar rumus dan array Excel. Karenanya, pastikan memahami keduanya dengan baik.

Cara Menggunakan Rumus TRANSPOSE Excel

Cara menggunakan fungsi TRANSPOSE sebagai rumus Excel adalah dengan memasukkan array sebagai parameter.

={"a", "b", "c", "d"}

=TRANSPOSE({"a","b","c","d"})

Rumus pertama menghasilkan array horisontal. TRANSPOSE mengubah orientasi array tersebut menjadi vertikal.

Sebaliknya, rumus pertama di bawah akan menghasilkan array vertikal. TRANSPOSE akan mengubah orientasi array menjadi horisontal.

={"a"; "b"; "c"; "d"}

=TRANSPOSE({"a"; "b"; "c"; "d"})

Rumus TRANSPOSE Excel dengan Range

Fungsi TRANSPOSE juga menerima parameter dalam bentuk range.

TRANSPOSE akan mengolah nilai apa pun yang dibawa oleh parameter. Bila kita ingin menyertakan header atau label keterangan lainnya, jangan lupa sertakan juga di dalam range parameter.

=TRANSPOSE(A1:C6)

Rumus di atas mengubah orientasi tabel A1:C6, kolom menjadi baris dan baris menjadi kolom, termasuk header.

Lihat bagaimana format-format yang dimiliki data sumber tidak disertakan di hasil rumus.

Data TRANSPOSE Tidak Nol

Perhatikan hasil rumus Gambar 01 cell I2.

Kekurangan (bila boleh disebut begitu) fungsi TRANSPOSE Excel adalah cell kosong diganti menjadi nol.

Bila kita ingin agar nilai kosong tetap kosong, gunakan kombinasi rumus TRANSPOSE dan IF.

=TRANSPOSE(IF(ISBLANK(A1:C6); ""; A1:C6))

Rumus di atas memeriksa setiap cell pada range A1:C6 dengan fungsi ISBLANK. Bila cell kosong atau blank (ISBLANK mengembalikan TRUE), maka IF akan memberikan string kosong bagi cell tersebut. Bila tidak (ISBLANK = FALSE), maka nilai asli akan diberikan.

Mengubah Rumus Menjadi Angka Excel

Seperti umumnya rumus Excel, perubahan terhadap data sumber akan tecermin di hasil rumus TRANSPOSE.

Bila data hasil rumus diinginkan sebagai data yang berdiri sendiri, gunakan fitur Paste Special.

Caranya adalah sebagai berikut:

1. Pilih seluruh rentang data hasil rumus.
2. Tekan kombinasi Ctrl+C untuk menyalin data ke clipboard.
3. Pilih cell di mana hasil copy paste akan ditempatkan. Kita dapat memilih lokasi yang sama dengan hasil rumus TRANSPOSE.
4. Klik kanan cell tersebut, pilih Paste Special untuk menampilkan kotak dialog dengan nama sama.
5. Pada kelompok Paste, pilih Values.
6. Klik OK.

Kombinasi Rumus XLOOKUP dan TRANSPOSE

Sampai sini teman-teman sudah paham bahwa fungsi TRANSPOSE pada Excel menerima dan mengolah array.

Tidak hanya itu, TRANSPOSE juga dapat mengolah array hasil olahan rumus lain.

=TRANSPOSE(XLOOKUP(1; ((B2:B6<3500000)*(C2:C6<3500000)); A2:C6))

Pada rumus di atas, potongan rumus XLOOKUP terdiri dari dua kriteria, yaitu mencari penjual dengan penjualan di bawah standar 3,500,000 selama dua tahun berturut ((B2:B6<3500000)*(C2:C6<3500000)).

Bila ketemu, XLOOKUP akan mengembalikan seluruh baris data (A2:C6) dari penjual bersangkutan.

TRANSPOSE kemudian mengubah orientasi array hasil XLOOKUP dari vertikal jadi horisontal.

Rumus TRANSPOSE Excel 2019 ke Bawah

Rumus-rumus pada contoh di atas berlaku bagi pengguna Excel 365 atau Excel 2021 ke atas. Sebabnya, Excel-excel versi ini memberlakukan dynamic array secara default.

Bagi teman-teman pengguna Excel versi 2019 ke bawah, menggunakan rumus TRANSPOSE agak lebih ribet sedikit.

Ada beberapa langkah yang harus diikuti.

1. Pilih range di worksheet di mana hasil rumus akan ditempatkan. Lebar kolom range harus sama dengan jumlah baris range parameter dan tinggi baris harus sama dengan jumlah kolom dari range parameter.
2. Tuliskan rumus TRANSPOSE dengan range parameter.
3. Selesaikan rumus dengan menekan kombinasi Ctrl+Shift+Enter.

Pada Excel versi 2019 ke bawah, rumus TRANSPOSE termasuk dalam golongan rumus CSE (Ctrl+Shift+Enter).

Dinamakan demikian karena pengguna perlu menekan kombinasi Ctrl+Shift+Enter, alih-alih hanya Enter, untuk menyelesaikan rumus.

Eksekusi CSE diperlukan bagi rumus-rumus array, di mana TRANSPOSE adalah salah satunya.