Ada beberapa cara untuk mendapatkan data tanpa redudansi. Salah satunya adalah dengan fungsi UNIQUE.
Artikel ini membahas mengenai rumus UNIQUE Excel, bentuk sintaks, serta cara penggunaannya pada beberapa kasus.
File: fungsi-unique-excel.xlsx.
Apakah Fungsi UNIQUE pada Excel Itu?
Fungsi UNIQUE pada Excel adalah fungsi untuk mengambil data unik di dalam suatu range atau array.
Fungsi UNIQUE mengembalikan data dalam bentuk array. Karena itu, pastikan tidak ada cell terisi di dalam range di mana hasil array tertumpah untuk menghindari pesan error #SPILL!.
Fungsi ini bisa dipakai bagi pengguna Excel 365 atau Excel 2021 ke atas.
Sintaks
UNIQUE(array; [by_col]; [exactly_once])
- array (wajib) adalah array atau range dari mana data unik akan dicari.
- by_col (opsional) adalah nilai Boolean, TRUE atau FALSE, yang menyatakan ke arah mana pencarian data unik dilakukan.
- TRUE akan membandingkan data unik kolom per kolom. Nilai ini digunakan bila data berorientasi horizontal.
- FALSE (default atau bila tidak dituliskan) akan mencari data dari baris ke baris. Nilai ini untuk data beriorientasi vertikal.
- exactly_once (opsional) adalah nilai logika untuk menentukan jenis keunikan data di dalam baris atau kolom.
- TRUE akan mengembalikan data yang sungguh cuma ada satu di sumber.
- FALSE (default atau bila tidak ditulis) akan mengembalikan semua data unik dan berbeda, terlepas dari jumlah redudansinya di dalam sumber.
Cara Menggunakan Rumus UNIQUE Excel
Rumus UNIQUE Excel Dasar
Dalam bentuk dasar, fungsi UNIQUE Excel hanya mensyaratkan satu parameter wajib di dalam rumus.
=UNIQUE(A2:A11)
Rumus di atas melihat ke dalam range A2:A11 dan mengembalikan setiap nama tanpa duplikasi.
Rumus-rumus berikut menggunakan struktur rumus UNIQUE secara lebih lengkap dengan parameter-parameter opsional menggunakan nilai default. Keduanya memberikan hasil yang sama dengan rumus di atas.
=UNIQUE(A2:A11; FALSE)
=UNIQUE(A2:A11; FALSE; FALSE)
Rumus UNIQUE Tabel Horizontal
Pada bagian sebelumnya, rumus mengambil data dari tabel dengan struktur vertikal.
Untuk range data dengan struktur tabel horizontal, berikan nilai TRUE bagi by_col.
Saat bernilai TRUE, rumus akan membandingkan data kolom demi kolom. Cocok bagi data yang terbentang secara horizontal.
=UNIQUE(B1:H2; TRUE)
Bila by_col bernilai default atau FALSE, sementara data horizontal, atau sebaliknya, maka hasilnya tidak akan sesuai harapan.
Rumus Mencari Data Unik dan Cuma Satu-satunya
Array hasil rumus UNIQUE Gambar 01 mengembalikan nilai unik. Data unik ini didapat dengan mengambil setiap nama yang ada dan berbeda, tanpa mengindahkan berapa banyak duplikasi untuk setiap nama terjadi.
Bila hanya ingin mendapatkan nama yang tidak memiliki duplikasi sama sekali di sumbernya, ganti nilai parameter exactly_once dari nilai defaultnya.
Rumus berikut mencari nama yang hanya muncul sekali di range A2:A11.
=UNIQUE(A2:A11; ;TRUE)
Mencari Data Unik di Kolom-kolom yang Berbeda
Mencari data unik yang berasal dari beberapa kelompok data dilakukan dengan menggabungkan setiap kelompok data.
Dalam konteks rumus UNIQUE, setiap kelompok (dalam bentuk kolom atau baris data) digabungkan ke dalam satu range.
=UNIQUE(A2:B11)
Rumus di atas mencari data unik dari kombinasi Nama (kolom A) dan Tanggal (kolom B). Seperti terlihat pada gambar, rumus mengembalikan lima baris dari sepuluh baris sumber data.
Perlu diingat bahwa UNIQUE hanya bisa mengakomodasi range-range berdekatan.
Mengurutkan Data Hasil Rumus UNIQUE
Rumus UNIQUE mengembalikan hasil sesuai dengan urutan data di sumber.
Untuk mengurutkan hasil rumus, gunakan fungsi SORT.
Dengan memodifikasi rumus pada bagian sebelumnya, kita mendapatkan rumus berikut.
=SORT(UNIQUE(A2:B11); {1,2})
Fungsi SORT di atas menerima array kembalian UNIQUE dan mengurutkannya berdasarkan kolom pertama (Nama) dan kolom kedua (Bulan).
Hasilnya seperti pada gambar di bawah. Bandingkan dengan hasil pada Gambar 04.
Rumus UNIQUE dengan Kriteria
Dari sananya, rumus UNIQUE Excel hanya mengambil satu yang berbeda dari data sumber, tanpa kriteria apa pun.
Untuk mengambil data unik dengan kriteria, gunakan kombinasi rumus UNIQUE dan FILTER.
Pertama, saring dulu data dengan rumus FILTER. Lalu, bungkus hasilnya dengan UNIQUE.
Rumus di bawah mencari bulan-bulan di mana Wahyu berjualan. Rumus FILTER mengambil hanya penjualan Wahyu lewat kriteria A2:A11="Wahyu". Kemudian, UNIQUE menyaring lagi hasilnya dengan menghilangkan duplikasi.
=UNIQUE(FILTER(A2:B11, (A2:A11="Wahyu")*(C2:C11<2000000), "Tidak ada data."))
Rumus UNIQUE Excel dengan Dua Kriteria atau Lebih
Untuk penyaringan dengan dua kriteria atau lebih, tambahkan evaluasi lain. Setiap evaluasi digabungkan dengan operator asterisk (untuk kriteria dengan operasi logika Dan), tanda tambah (untuk operasi Atau), atau gabungan keduanya.
Rumus di bawah menampilkan data pada bulan kapan saja Wahyu melakukan penjualan di bawah 2,000,000. Dari kalimat ini, rumus terdiri dari dua kriteria, yaitu:
- Penjualan Wahyu, DAN.
- Penjualan di bawah 2,000,000.
Berhubung kriteria mensyaratkan kondisi Dan, maka kami menggunakan operator asterisk untuk menggabungkannya.
=UNIQUE(FILTER(A2:B11, (A2:A11="Wahyu")*(C2:C11<2000000), "Tidak ada data."))
Rumus UNIQUE Excel Tidak Bekerja
Seperti fungsi-fungsi lainnya, UNIQUE punya kemungkinan tidak bekerja sebagaimana yang kita inginkan.
Ada beberapa sebab yang bisa kita telaah.
Rumus UNIQUE Tidak Muncul di Excel
Ada, kok.
Tapi, UNIQUE hanya tersedia di Excel 365 dan Excel 2021 ke atas.
Bagi pengguna Excel 2021 ke bawah – seperti Excel 2019, 2013, atau 2010 – dan tidak mau upgrade, alternatifnya adalah menggunakan Excel web.
Pesan Error #NAME!
Rumus Excel, seperti DATEDIF, bisa diketikkan langsung di Excel, walau pun tanpa popup pembantu, dan akan memberikan hasil.
Kondisi ini tidak berlaku untuk UNIQUE.
Mengetikkan langsung rumus UNIQUE pada versi Excel di bawah Excel 2021 akan berakibat tampilnya pesan error #NAME!.
Pesan Error #SPILL!
Pesan #SPILL! terjadi ketika array hasil rumus UNIQUE Excel tumpah ke dalam range yang salah satu cellnya memiliki nilai atau format tertentu.
Untuk menghindarinya, hilangkan kemungkinan-kemungkinan yang menyebabkan terjadinya error ini.
Pesan Error #REF!
Bila data sumber berasal dari file atau workbook lain, pastikan workbook tersebut terbuka. Bila tidak, pesan error #REF! terjadi, alih-alih hasil yang diinginkan.