Fungsi DATEDIF Excel: Mencari Selisih Dua Tanggal

Berapa selisih hari antara 21 Maret 2007 dan 26 Agustus 2024? Melakukan perhitungan manual bisa memakan waktu, bukan? Fungsi DATEDIF di Excel mempermudah proses ini dengan memberikan hasil secara cepat dan akurat.

Untuk melihat hasil dalam format Excel, unduh file berikut:

File: fungsi-datedif-excel.xlsx.

Daftar Isi

Apa Itu Fungsi DATEDIF di Excel?

Fungsi DATEDIF digunakan untuk menghitung selisih waktu antara dua tanggal, baik dalam satuan hari, bulan, atau tahun.

Namun, DATEDIF tidak muncul otomatis dalam daftar fungsi Excel, karena dirancang sebagai fitur kompatibilitas untuk software Lotus 1-2-3. Fungsi ini harus ditulis secara manual, tanpa bantuan auto-complete Excel.

Peringatan:Beberapa pengguna menyarankan untuk menghindari penggunaan DATEDIF karena:

Fungsi ini mungkin dihapus oleh Microsoft di masa depan.
Terdapat bug yang belum diperbaiki, berpotensi menghasilkan perhitungan yang salah.

Sintaks dan Parameter Fungsi DATEDIF

Sintaksis

DATEDIF(start_date; end_date; unit)

start_date: Tanggal awal perhitungan.
end_date: Tanggal batas akhir perhitungan.
unit: Satuan waktu perhitungan (opsional).
- Y: Jumlah tahun penuh antara dua tanggal.
- M: Jumlah bulan penuh antara dua tanggal.
- D: Jumlah hari penuh antara dua tanggal.
- MD: Jumlah hari tanpa mempertimbangkan bulan atau tahun.
- YM: Jumlah bulan tanpa mempertimbangkan hari atau tahun.
- YD: Jumlah hari tanpa mempertimbangkan tahun.

Semua satuan waktu dianggap sama baik dituliskan dalam huruf besar atau kecil.

Menggunakan DATEDIF di Excel

Menghitung Selisih Tahun

Untuk menghitung tahun, gunakan unit = y.

DATEDIF membulatkan hasil tahun ke bawah. Contoh:

=DATEDIF(DATE(2023; 11; 1); DATE(2024; 10; 1); "y")

Hasil: 0 tahun karena belum genap satu tahun.

=DATEDIF(DATE(2023; 11; 1); DATE(2024; 11; 1); "y")

Hasil: 1 tahun karena sudah genap satu tahun.

Menghitung Selisih Bulan

Selisih bulan dihitung menggunakan unit = m.

DATEDIF membulatkan hasil bulan ke bawah. Contoh:

=DATEDIF(DATE(2023; 11; 1); DATE(2023; 12; 1); "m")

Hasil: 1 bulan, karena jarak satu bulan penuh.

=DATEDIF(DATE(2023; 11; 1); DATE(2024; 1; 17); "m")

Hasil: 2 bulan, karena jarak lebih dari 2 bulan, tapi tidak sampai 3.

Menghitung Selisih Hari

Selisih hari dihitung menggunakan unit periode D:

=DATEDIF("2023-12-01"; "2023-12-22"; "d")

Hasil: 21 hari antara 1 Desember 2023 dan 22 Desember 2023.

Menghitung Selisih Tanpa Mengindahkan Hari, Bulan, atau Tahun

Tanpa Bulan dan Tahun. Unit MD hanya menghitung komponen hari.
```
=DATEDIF("2023-10-01"; "2027-04-22"; "md")
```
Hasil: 21 hari, terlepas dari bulan dan tahun.
Tanpa Tahun dan Hari. Unit YM untuk hanya menghitung selisih bulan penuh.
```
=DATEDIF("2023-11-01"; "2025-01-01"; "YM")
```
Hasil: 2 bulan, karena jarak antara November dan Januari, terlepas tahun.
Tanpa Tahun. Unit YD hanya menghitung selisih hari tanpa mempertimbangkan tahun.
```
=DATEDIF("2023-12-01"; "2028-01-31"; "yd")
```
Hasil: 61 hari.

Menghitung Umur dengan DATEDIF

Untuk menghitung umur secara detail dalam tahun, bulan, dan hari, gunakan DATEDIF dengan unit:

Y: pengurangan tahun.
YM: pengurangan bulan.
MD: pengurangan hari.

="Usia " & DATEDIF(A2; B2;"y") & " tahun, " & DATEDIF(A2; B2; "ym") & " bulan, dan " & DATEDIF(A2; B2; "md") & " hari."

Rumus menghitung selisih tanggal dari 26 Agustus 1962 (A2) dan hari ini (B2. Tanggal rumus dibuat: 16 April 2025).

Hasil: Usia 62 tahun, 7 bulan, dan 21 hari..

Penutup

Fungsi DATEDIF di Excel adalah alat untuk menghitung selisih tanggal dalam berbagai satuan waktu. Walaupun memiliki beberapa keterbatasan, dengan pemahaman yang tepat, DATEDIF dapat digunakan untuk analisis data yang lebih mendalam.

Mohon hubungi kami melalui kolom komentar bila ada pertanyaan lebih lanjut.