Cara Menghitung Umur di Excel dengan Berbagai Rumus

Menghitung umur adalah perhitungan sederhana tetapi membutuhkan ketelitian, terutama dalam menangani format tanggal di Excel. Artikel ini membahas berbagai metode untuk menghitung umur berdasarkan tahun, bulan, dan hari menggunakan beberapa fungsi bawaan Excel seperti DATEDIF, YEARFRAC, DAYS360, serta cara menangani error dalam perhitungan umur.

File: menghitung-umur-excel.xlsx.

Daftar Isi

Apa Itu Menghitung Umur?

Menghitung umur adalah selisih waktu antara tanggal lahir seseorang dengan tanggal saat ini.

Umur biasanya dihitung dalam tahun. Jika ingin presisi lebih, umur dapat menyertakan bulan dan hari.

Cara Menghitung Umur di Excel: Dasar

Metode paling sederhana untuk menghitung umur adalah dengan mengurangi tanggal lahir dari tanggal saat ini menggunakan fungsi TODAY.

=(TODAY()-A2)/365

Rumus membagi hasil pengurangan tanggal dengan 365 untuk mendapatkan umur. Karena perhitungan berbasis jumlah hari dalam setahun (365), hasilnya bisa sedikit meleset jika melibatkan tahun kabisat.

Untuk membulatkan umur ke ulang tahun terdekat, kombinasikan dengan fungsi INT atau ROUND.

=INT((TODAY()-A2)/365)

=ROUND((TODAY()-A2)/365; 0)

Menghitung Usia dengan Fungsi DAYS360

Fungsi DAYS360 menghitung selisih di antara 2 tanggal berdasarkan kalender keuangan 360 hari, bukan 365 atau 366.

=DAYS360(A2; TODAY()) / 360

Menghitung umur di Excel dengan fungsi DAYS360.

Bulatkan hasil dengan INT atau ROUND:

=INT(DAYS360(A2; TODAY()) / 360)

=ROUND(DAYS360(A2; TODAY()) / 360; 0)

Menghitung Umur dengan Rumus DATEDIF

Menghitung Tahun Saja

Untuk mendapatkan hanya tahun, gunakan rumus DATEDIF dengan parameter Y.

=DATEDIF(A2; TODAY(); "Y")

Umur dengan Tahun, Bulan, dan Hari

Rumus berikut menghitung usia berdasarkan tahun, bulan, dan hari.

=DATEDIF(A2; TODAY(); "Y") & " Tahun, " & DATEDIF(A2; TODAY(); "YM") & " Bulan, " & DATEDIF(A2; TODAY(); "MD") & " Hari"

Rumus DATEDIF menghitung usia dengan tahun, bulan, dan hari.

Baca: Fungsi DATEDIF Excel.

Menghitung Umur dengan Rumus YEARFRAC

YEARFRAC menghitung nilai pecahan di antara dua tanggal. Fungsi INT membulatkan angka ke ulang tahun terdekat di bawah.

=INT(YEARFRAC(A2; TODAY()))

Menghitung Usia dengan Fungsi YEAR dan MONTH

Jika ingin alternatif DATEDIF, gunakan kombinasi YEAR dan MONTH.

=YEAR(TODAY()) - YEAR(A2) - IF(MONTH(TODAY()) < MONTH(A2); 1; 0)

Menghitung usia dengan IF, YEAR, dan MONTH.

Mengapa menggunakan rumus ini?

Memberikan kendali lebih pada pengguna terhadap cara Excel menghitung bulan.
Menghindari potensi di masa depan jika fungsi DATEDIF tidak lagi didukung oleh Excel.

Menghindari Error Saat Menghitung Umur

Bila input tanggal tidak valid, rumus akan menghasilkan error #VALUE!. Gunakan IFERROR untuk menangani error dan menampilkan pesan lebih informatif.

=IFERROR((TODAY()-A2)/365; "Tanggal Tidak Valid")

Pesan Tanggal Tidak Valid akan muncul jika format tanggal tidak benar.

Menangani error menghitung umur dengan IFERROR.

Catatan: Tanggal pada screenshot menggunakan format bahasa Indonesia, sementara Excel kami Bahasa Inggris.

Penutup

Menghitung umur di Excel adalah keterampilan penting dalam berbagai bidang seperti SDM, keuangan, kesehatan, dan pendidikan. Dengan memahami fungsi seperti DATEDIF, TODAY(), IFERROR, serta metode alternatif seperti YEARFRAC dan DAYS360, kita dapat melakukan perhitungan usia dengan lebih presisi dan fleksibilitas.