Fungsi FLOOR, CEILING, MROUND: Pembulatan Kelipatan

Dalam pengolahan data di Excel, pembulatan angka ke kelipatan tertentu sering kali diperlukan untuk berbagai tujuan, seperti perhitungan harga, kuantitas barang, hingga perencanaan waktu.

Excel menyediakan tiga fungsi utama untuk tujuan ini: MROUND, CEILING, dan FLOOR. Artikel ini membahas cara kerja, sintaks, dan penerapan ketiga fungsi tersebut dalam berbagai situasi.

Unduh file berikut untuk memahami contoh-contoh rumus lebih baik.

File: fungsi-mround-ceiling-floor-excel.xlsx.

Apa Itu Fungsi MROUND, CEILING, dan FLOOR di Excel?

Fungsi MROUND

Fungsi MROUND digunakan untuk membulatkan angka ke kelipatan yang diinginkan.

Sintaks

MROUND(number; multiple)

• number (wajib): angka yang ingin dibulatkan.
• multiple (wajib): kelipatan angka yang digunakan sebagai acuan pembulatan.

Hal Penting Mengenai MROUND

• Jika number dan multiple berbeda tanda, positif dan negatif atau sebaliknya, hasilnya #NUM!.
• Jika number adalah kelipatan multiple, pembulatan tidak dilakukan.
• Jika sisa pembagian number dengan multiple lebih besar atau sama dengan setengah nilai multiple, pembulatan dilakukan ke atas. Jika kurang dari setengah, dibulatkan ke bawah.
  • =MROUND(21; 5) → 20
  • =MROUND(23; 5) → 25 (karena 3 lebih besar dari setengah dari 5).

Fungsi CEILING

Fungsi CEILING membulatkan angka ke atas ke kelipatan terdekat dari suatu angka.

Sintaks

CEILING(number; significance)

• number (wajib): angka yang ingin dibulatkan.
• significance (wajib): kelipatan yang digunakan sebagai acuan pembulatan.

Hal Penting Mengenai CEILING

• Jika number atau significance bukan angka, hasilnya #VALUE!.
• Jika number positif dan significance negatif, hasil #NUM!.
• Jika number adalah kelipatan significance, tidak ada pembulatan.
• Jika number dan significance negatif, hasil dibulatkan menjauhi nol.
• Jika number negatif dan significance positif, hasil dibulatkan mendekati nol.
  • =CEILING(11,25; 3) → 12
  • =CEILING(-11,25; 3) → -9 (karena pembulatan dilakukan ke atas mendekati nol).

Fungsi FLOOR

Fungsi FLOOR membulatkan nilai ke bawah ke kelipatan angka tertentu.

Sintaks

FLOOR(number; significance)

• number (wajib): angka yang ingin dibulatkan.
• significance (wajib): kelipatan yang digunakan sebagai acuan pembulatan.

Hal Penting Mengenai FLOOR

• Jika number dan significance bukan angka, hasil adalah #VALUE!.
• Jika number adalah kelipatan significance, tidak ada pembulatan.
• Jika number dan significance negatif, hasil dibulatkan ke bawah.
• Jika number negatif dan significance positif, hasil dibulatkan ke atas.
• Jika number negatif dan significance positif, number dibulatkan mendekati nol.
  • =FLOOR(11,25; 3) → 9
  • =FLOOR(-11,25; 3) → -12

Cara Menggunakan Fungsi MROUND, CEILING, dan FLOOR

Rumus MROUND

Rumus membulatkan angka ke kelipatan 3 (B2), yaitu 12 dan 9.

=MROUND(A2; B2)

• Jika A2 = 11,25087719. Hasil = 12 (11,25087719 lebih dekat ke 12).
• Jika A2 = 10,25087719. Hasil = 9 (10,25087719 lebih dekat ke 9).

Rumus CEILING

Rumus membulatkan angka A2 ke atas berdasarkan kelipatan B2.

=CEILING(A2; B2)

Dengan B2 bernilai 3:

• A2=11,25087719, B2=3 → Hasil 12.
• A2=10,25087719, B2=3 → Hasil 12.

Rumus FLOOR

Rumus membulatkan angka A2 ke bawah mendekati kelipatan angka di cell B2.

=FLOOR(A2; B2)

Jika B2 = 3, maka:

• Rumus membulatkan 11,25087719 ke angka 9.
• Rumus membulatkan 10,25087719 ke angka yang sama, yaitu 9.

Contoh-contoh Penggunaan Dalam Kasus Nyata

Membulatkan Harga di Excel

Beberapa toko membulatkan hasil belanjaan ke ratusan terdekat untuk mempermudah kembalian.

=MROUND(A4; $B$1)

Membulatkan Waktu di Excel

Rumus berikut membulatkan jam lembur ke 15 menit terdekat untuk mempermudah perhitungan gaji. 15 menit adalah ¼ atau 0,25 dari 60 menit atau 1 jam.

=MROUND(A4; 0,25)

=HOUR(F3)+MINUTE(F3)/60+SECOND(F3)/3600

Kombinasi MROUND dan IF: Menghitung Diskon Belanja

Toko memberikan diskon 10% jika belanja lebih dari Rp 100.000. Baik mendapat potongan atau tidak, harga akhir dibulatkan ke ratusan terdekat.

=IF(D2>$B$2; MROUND(D2*(1-$B$3); $B$1); MROUND(D2; $B$1))

Membulatkan Kuantitas Barang

Perusahan memiliki produk dengan isi 5 item per kemasan. Bila estimasi tidak pas kelipatan 5, Perusahaan membulatkannya ke atas ke kelipatan 5 terdekat agar tidak ada barang tersisa.

=CEILING(A4; $B$1)

Mengatur Jadwal Meeting

Manajemen Fasilitas menjadwalkan pemakaian ruang meeting.

Jika durasi tidak pas kelipatan ½ jam, maka:

• Durasi dibulatkan ke ½ jam terdekat di atas.
• ½ jam akan ditambahkan ke durasi.

=CEILING(A2; 0,5)+IF(MOD(A2;0,5)=0; 0; 0,5)

Mengambil Harga Tertinggi Setelah Diskon

Rumus berikut mencegah harga jual jatuh di bawah harga minimum yang ditetapkan. Rumus memilih harga tertinggi di antara harga minimum dan harga setelah diskon yang dibulatkan ke ratusan terdekat.

=MAX(B2; FLOOR(A2*(1-C2); 100))

Tambahan: Fungsi ISO.CEILING Excel

Fungsi ISO.CEILING membulatkan angka ke atas ke bilangan bulat terdekat atau ke kelipatan angka tertentu.

Fungsi ini ada untuk mendukung kompatibilitas dengan Excel versi-versi sebelumnya. Karenanya, fungsi ini harus dituliskan secara penuh, tanpa bantuan intellisense.

Sintaks

ISO.CEILING(number; [significance])

• number (wajib): angka yang dibulatkan.
• significance (opsional): angka yang kelipatannya yang menjadi acuan pembulatan.

Contoh Rumus ISO.CEILING

• Rumus membulatkan angka ke bilangan bulat terdekat. Pembulatan tidak dilakukan jika angka sudah bulat.
  =ISO.CEILING(3,14) → 4
  =ISO.CEILING(3) → 3
• Rumus membulatkan angka ke atas ke kelipatan 10.
  =ISO.CEILING(-17,08; 5) → -15
  =ISO.CEILING(17,08; 5) → 20

Penutup

Fungsi MROUND, CEILING, FLOOR, dan ISO.CEILING di Excel memungkinkan pembulatan angka dengan berbagai metode. Dengan memahami perbedaan dan penerapannya, kita dapat mengelola angka lebih akurat dalam berbagai skenario.