Fungsi FLOOR.MATH di Excel: Pembulatan ke Bawah ke Kelipatan Tertentu dengan Kontrol Angka Negatif

Di Excel, pembulatan tidak selalu berarti mendekatkan angka ke bilangan bulat terdekat. Dalam beberapa kasus pembulatan, kita terkadang perlu mendorong nilai ke bawah ke kelipatan tertentu untuk memperoleh hasil yang aman, konsisten, dan mudah dikelompokkan.

Fungsi FLOOR.MATH adalah salah satu solusi Excel untuk kondisi ini.

Artikel ini membahas fungsi FLOOR.MATH Excel: informasi dasar, tips, contoh kasus nyata, perbedaan dengan fungsi-fungsi lain yang serupa, serta contoh-contoh kesalahan umum.

File: fungsi-floor-math-excel.xlsx

Apa Itu Fungsi FLOOR.MATH di Excel?

Fungsi FLOOR.MATH adalah fungsi yang membulatkan ke bawah ke kelipatan terdekat.

Fungsi ini memiliki kontrol untuk menentukan bagaimana angka negatif dibulatkan, mendekati atau menjauhi nol.

Sintaks
FLOOR.MATH(number; [significance]; [mode])

Penjelasan:

• number (wajib): nilai yang ingin dibulatkan ke bawah.
• significance (opsional): kelipatan tujuan pembulatan. Parameter ini bernilai default 1 bila tidak dituliskan.
• mode (opsional): mengontrol pembulatan untuk angka negatif.
  • 0 (atau diabaikan): angka negatif dibulatkan ke bawah, menjadi lebih kecil atau lebih negatif, mengikuti aturan matematika.
  • 1: angka negatif dibulatkan menuju nol, sehingga hasilnya lebih konservatif untuk kasus tertentu seperti toleransi minus, selisih, atau koreksi.

Kapan Menggunakan Fungsi FLOOR.MATH?

• Mengunci nilai agar tidak pernah melewati batas atas, misalnya batas diskon maksimum, batas kuota, batas target, atau “maksimal yang boleh ditagih”.
• Membuat pengelompokan (binning) yang konsisten ke interval tetap, seperti untuk segmentasi, histogram, klasifikasi, dan bucket KPI.
• Normalisasi input agar selalu jatuh pada grid tertentu, misalnya kelipatan 0,25 jam, 50 gram, atau 5 menit, sebelum hasilnya dipakai oleh rumus lain.
• Menangani angka negatif dengan aturan yang dapat dikendalikan melalui mode, untuk hasil yang lebih mudah diprediksi.
• Menghindari efek samping pembulatan ke atas yang bisa membuat hasil terlihat “lebih baik” dari data aslinya (overstatement), misalnya pada laporan kapasitas, stok, atau SLA.
• Mengatasi masalah pecahan desimal akibat floating-point dengan menurunkan nilai ke kelipatan yang masuk akal (contoh: 0,01 atau 0,001) sebelum diolah lebih lanjut.

Tips Menggunakan Rumus FLOOR.MATH

• number dan significance harus angka.
• Tentukan significance sesuai kasus atau konteks.
• Uji perilaku angka negatif untuk menentukan apakah sesuai kebutuhan, yaitu menuju atau menjauhi nol.
• Pertimbangkan penggunaan significance kecil, misalnya 0,01, untuk menurunkan noise desimal sebelum perbandingan logika.
• Gunakan IFERROR atau validasi input jika sumber data berpotensi kosong atau berformat teks.
• Jangan gunakan FLOOR.MATH untuk pembulatan ke digit tertentu—ROUND lebih tepat untuk kebutuhan ini.
• Jangan mengandalkan FLOOR.MATH hanya untuk presisi desimal; periksa kebutuhan dulu dan pertimbangkan toleransi pembulatan.
• Kuasai perbedaan sifat FLOOR.MATH saat mode bernilai 1 atau 0.

Contoh Rumus FLOOR.MATH di Excel

Estimasi Biaya Pengiriman Kontainer

Sebuah perusahaan menghitung berapa kontainer yang dibutuhkan untuk menampung sejumlah barang produksi. Sebuah kontainer mampu menampung 300 item. Perusahaan membulatkan ke bawah agar pengiriman hanya menghitung kontainer yang terisi penuh, dan mengabaikan sisanya untuk pengiriman di kemudian hari.

=FLOOR.MATH(B5/$B$1; 1)

Pembulatan Jam Kerja Produksi

Sebuah pabrik membayar jam lembur per 30 menit. Pabrik menghitung jam kerja efektif untuk hari lembur Sabtu dan Minggu dengan pembulatan ke bawah ke 30 menit. Dengan sistem ini, karyawan yang bekerja 7 jam 45 menit dihitung 7 jam 30 menit.

=FLOOR.MATH((C2-B2)*24; 0,5)

Menghitung Koreksi Akuntansi Bulanan

Kepala akuntansi sedang menyusun laporan bulanan dan menghitung koreksi bersih setelah pembulatan. Ia membulatkan angka dengan FLOOR.MATH ke Rp 100-an bawah terdekat. Selain itu, ia juga menggunakan mode = 1 untuk:

• Membulatkan nilai negatif mendekati nol untuk menghindari overstatement kerugian
• Dan membulatkan nilai positif mendekati nol untuk menghindari overstatement keuntungan.

=FLOOR.MATH(SUM(D2:D20);100;1)

Audit Kualitas dengan Pembulatan Negatif

Tim audit kualitas di pabrik komponen otomotif sedang rapat untuk menghadapi audit. Data deviasi dari 49 sampel menunjukkan rata-rata penyimpangan -0,081 mm dari spesifikasi. Untuk audit, tim memutuskan menggunakan FLOOR.MATH dengan mode = 1 dan kelipatan 0,1. Dengan cara ini:

• -0,081 dibulatkan menjadi nol
• -0,15 menjadi -0,1

Cara ini membantu tim dan auditor dalam prinsip materialistis, prinsip konservatisme, dan standarisasi laporan.

=FLOOR.MATH(AVERAGE(E2:E50); 0,1; 1)

Akuntansi Multi‑Negara

Sebuah perusahaan memiliki 3 cabang di Indonesia, Malaysia, dan Singapura. Setiap negara memiliki sistem pembulatan sendiri. Untuk pencatatan keuangan, direktur Finance dan Accounting meminta agar dibuatkan rumus untuk membantu otomatisasi.

=IF(D2<0; IF(C2="Indonesia"; FLOOR.MATH(D2; 1000; 0); FLOOR.MATH(D2; 1000; 1)); FLOOR.MATH(D2; 1000))

Dengan rumus ini:

• Jika Indonesia dan negatif, nilai dibulatkan lebih negatif, sesuai asas konservatif PSAK.
• Selebihnya, jika negatif maka dibulatkan ke atas. Jika positif, dibulatkan ke bawah.

Perhitungan Bunga Sesuai Risiko                                   

Sebuah bank menyusun solusi berupa rumus untuk mengakomodasi tim konsumtif yang ingin agar nasabah diuntungkan dan tim produktif yang ingin agar bank mendapat margin lebih.

=IF(D2="Konsumtif"; FLOOR.MATH(E2 * 0,02; 1000); IF(D2="Produktif"; FLOOR.MATH(E2 * 0,015; 1000; 1); FLOOR.MATH(E2 * 0,01; 500)))

Dengan rumus di atas:

• Konsumtif: FLOOR.MATH(saldo × 2%; 1000) → Selalu ke bawah. Nasabah KPR atau kendaraan diberi keringanan.
• Produktif: CEILING.MATH(saldo × 1,5%; 1000) → Selalu ke atas. Bank mendapat tambahan dari pengusaha atau UMKM.
• Mikro: FLOOR.MATH(saldo × 1%; 500) → Kelipatan 500 ke bawah. Lebih ramah nasabah kecil.

Penentuan Harga Jual Psikologis

Pemilik toko XYZ melihat bahwa tokonya memiliki lebih banyak pelanggan di akhir pekan ketimbang di hari biasa. Pemilik toko menaikkan harga sebesar 30% dari harga dasar. Agar lebih kompetitif, terutama untuk beberapa produk tertentu, pemilik membulatkan angka ke 500 ke bawah di hari biasa, dan 500 ke atas di akhir pekan.

=IF(NOT(OR(C2="Sabtu"; C2="Minggu")); FLOOR.MATH(B2*1,3; 500; 1); CEILING.MATH(B2*1,3; 500))

Simulasi Risiko yang Tidak Boleh Membesar

Tim manajemen risiko sebuah bank sedang menganalisis model Value at Risk (VaR) terbaru. Hasil model =POWER(A2;B2) menghasilkan angka-angka kecil hingga besar, positif dan negatif. Untuk menghindari kerugian lebih besar karena pembulatan biasa, analis risiko menggunakan FLOOR.MATH dengan mode = 1. Dengan cara ini:

• Nilai positif 0,64 dibulatkan menjadi 0,60. Konservatif untuk risiko positif
• Nilai negatif -2,46 menjadi -2,45. Kerugian tidak diperbesar

Walaupun selisih antara 0,64 dan 0,60 terlihat kecil, dengan keterpaparan atau eksposur sebesar Rp 1.000.000.000, selisih risiko adalah Rp 40.000.000. Cukup signifikan, terlebih lagi keterpaparan lebih besar lagi.

=FLOOR.MATH(POWER(A4;B4);0,05;1)

Pembulatan Multikolom dengan MAP + LAMBDA

Sebuah perusahaan keuangan mengimplementasikan sistem baru. Di dalam sistem ini, setiap transaksi memiliki aturan pembulatan sendiri. Alih-alih membuat rumus satu per satu (atau menyalinnya) secara manual, manajer keuangan menggunakan MAP untuk membantu pemetaan variabel dan LAMBDA untuk menentukan setiap pasangan (x; k) akan dipasangkan dengan mode = 1.

Dengan mode = 1, setiap angka negatif akan dibulatkan ke atas untuk memperkecil kerugian, dan angka positif dibulatkan ke bawah agar lebih konservatif.

=MAP(A2:A19;B2:B19;LAMBDA(x;k;FLOOR.MATH(x;k;1)))

Kesalahan Umum Rumus FLOOR.MATH dan Solusinya

Perbedaan FLOOR.MATH, FLOOR, MROUND, dan ROUNDDOWN

FLOOR.MATH selalu membulatkan ke bawah ke kelipatan tertentu (dengan opsi mengubah perilaku untuk negatif).

Penutup

FLOOR.MATH adalah fungsi pembulatan ke bawah yang modern, fleksibel, dan aman untuk dataset campuran. Dengan kontrol mode untuk angka negatif, fungsi ini menjadi pilihan ideal untuk keuangan, logistik, risiko, dan analisis data yang membutuhkan hasil konservatif dan konsisten.