Fungsi SUMIFS Excel: Rumus Menjumlahkan dengan Banyak Kriteria

Fungsi SUMIFS adalah salah satu rumus Excel penting untuk analisis data. Dengan SUMIFS, kita bisa menjumlahkan nilai berdasarkan lebih dari satu kriteria sekaligus. Rumus ini berguna untuk mengelola anggaran, melacak penjualan, atau menganalisis kumpulan data besar.

Artikel ini membahas cara kerja SUMIFS, kapan menggunakannya, tips praktis, contoh rumus, kesalahan umum, serta perbedaan dengan SUMIF.

File: fungsi-sumifs-excel.xlsx

Apa Itu Fungsi SUMIFS di Excel?

SUMIFS adalah rumus Excel yang menjumlahkan nilai dalam suatu range jika memenuhi satu atau beberapa kondisi.

Tidak seperti pendahulunya, SUMIF, yang hanya mendukung satu kriteria, SUMIFS dapat menangani dua atau lebih kriteria, sehingga ideal untuk analisis data yang lebih kompleks.

SUMIFS bisa menggunakan hingga 127 pasang kriteria, menjadikannya cocok untuk data besar.

Sintak
SUMIFS(sum_range; criteria_range1; criteria1; [criteria_range2; criteria2]; ...)

Keterangan:

• sum_range (wajib): Range dari nilai-nilai yang akan dijumlahkan
• criteria_range1 (wajib): Range yang akan dievaluasi
• criteria1 (wajib): Kriteria bagi range pertama
• criteria_range2 sampai criteria_range127 (opsional): Range tambahan
• criteria2 sampai criteria127 (opsional): Kriteria tambahan

Kapan dan Mengapa Menggunakan SUMIFS?

SUMIFS umum digunakan untuk menganalisis atau mengagregasi data berdasarkan beberapa kondisi. Penggunaan umum meliputi:

• Menjumlahkan penjualan berdasarkan produk dan wilayah
• Menghitung pengeluaran untuk departemen dan periode waktu tertentu
• Mengagregasi jam kerja berdasarkan proyek dan status karyawan

SUMIFS paling efektif jika data disusun dalam kolom dan baris terstruktur dengan header jelas.

Tips Menggunakan Rumus SUMIFS Excel

• Pastikan semua range argumen berukuran sama
• Gunakan header dan format data konsisten
• Gunakan referensi absolut jika rumus disalin ke cell lain
• Pastikan kriteria sesuai dengan jenis data (angka, teks, tanggal)
• Untuk kriteria tunggal, gunakan SUMIF agar lebih sederhana
• Bersihkan data dari spasi berlebih atau karakter tak terlihat
• Ingat: semua kriteria di SUMIFS digabungkan dengan logika And
• Perbandingan default adalah sama dengan (=)

Contoh Rumus SUMIFS Excel

Rumus SUMIFS dengan Dua Kriteria

Rumus di bawah menghitung total penjualan Nangka oleh Wayan.

=SUMIFS(D2:D11; B2:B11; "Wayan"; C2:C11; "Nangka")

Untuk fleksibilitas, tempatkan setiap nilai di dalam referensi.

=SUMIFS(D2:D11; B2:B11; B14; C2:C11; C14)

Di mana:

• D2:D11 adalah range yang akan dijumlahkan
• B2:B11 adalah range di mana kriteria pertama diterapkan
• B14 adalah nilai kriteria bagi B2:B11
• C2:C11 adalah range bagi kriteria kedua
• C14 adalah nilai kriteria bagi C2:C11

Rumus Antar Worksheet

Rumus berikut menggunakan menghitung penjualan Manggis oleh Eko pada worksheet yang berbeda.

Perhatikan penggunaan referensi beda worksheet.

=SUMIFS('01'!D2:D11; '01'!B2:B11; '03'!A2; '01'!C2:C11; '03'!B2)

SUMIFS dengan Kriteria Dua Tanggal

Rumus berikut menghitung total penjualan di antara dua tanggal, yaitu dari 1 Februari 2025 sampai 28 Februari 2025.

Rumus menempatkan operator pembanding (>= dan <=) sebagai teks. Kedua operator digabungkan dengan nilai referensi menggunakan operator ampersand (&).

=SUMIFS(B2:B11; A2:A11; ">="&A2; A2:A11; "<="&A6)

SUMIFS dengan Kriteria Or

Rumus SUMIFS dengan kriteria Or dicapai dengan menggunakan rumus array, baik range atau pun konstan.

Rumus di bawah menghitung penjualan Eko atau Indra (E1:E2). Hasil dijumlahkan menggunakan SUM untuk mendapatkan total.

=SUM(SUMIFS(B2:B11; A2:A11; E1:E2))

SUMIFS dengan Wildcard

Rumus berikut menghitung penjualan bulan Desember oleh para penjual bernama Eko menggunakan wildcard.

Rumus juga menggunakan EOMONTH untuk menentukan awal dan akhir bulan secara fleksibel.

=SUMIFS(C2:C11; B2:B11; F1; A2:A11; ">="&EOMONTH(TODAY();-1)+1; A2:A11; "<="&EOMONTH(TODAY();0))

Kesalahan Umum Pada Rumus SUMIFS

Perbedaan SUMIFS vs SUMIF

Kesimpulan

Fungsi SUMIFS adalah alat penting untuk menjumlahkan data dengan banyak kriteria di Excel. Dengan memahami sintaksis, tips penggunaan, dan contoh rumus, kita bisa menghindari kesalahan umum dan meningkatkan efisiensi analisis.

SUMIFS melengkapi SUMIF: gunakan SUMIF untuk kasus sederhana, dan SUMIFS untuk kebutuhan analisis yang lebih kompleks.