Saat bekerja dengan Excel, kadang kita butuh menghasilkan nomor urut, seperti 1, 2, 3, dan seterusnya. Biasanya, kita menulis angka-angka tersebut secara manual.
Tapi dengan rumus SEQUENCE Excel, membuat nomor urut, baik bentuk dasar atau pola tertentu jadi lebih mudah.
File: fungsi-sequence-excel.xlsx.
Apakah Rumus SEQUENCE Excel Itu?
Fungsi SEQUENCE pada Excel adalah fungsi yang mengembalikan daftar urutan angka.
Karena berupa daftar, maka kembalian SEQUENCE adalah array.
Saat ini, SEQUENCE hanya terdapat di Excel 365, Excel web, dan Excel 2021 ke atas.
Sintaks
SEQUENCE(rows;[columns];[start];[step])
- rows (wajib) adalah jumlah baris dari array yang akan dikembalikan.
- rows harus berupa angka positif, tidak bisa negatif.
- columns (opsional) adalah jumlah kolom dari array yang akan dikembalikan.
- columns harus berupa angka positif, tidak boleh negatif.
- columns memiliki nilai default 1 bila tidak dinyatakan. Nilai ini berarti array terdiri dari satu kolom.
- start (opsional) adalah angka pertama di dalam daftar.
- start dapat berupa angka positif, negatif, bulat, atau desimal.
- Bila tidak dituliskan, nilai default start adalah 1.
- step (opsional) adalah angka yang ditambahkan ke setiap angka di dalam daftar untuk menghasilkan angka berikutnya.
- step dapat berupa angka positif, negatif, bulat, atau desimal.
- Bila tidak disertakan, Excel akan menggunakan nilai default 1.
Cara Menggunakan Rumus SEQUENCE Excel
Cara Membuat Nomor Urut ke Bawah di Excel
Bila hanya menggunakan parameter wajib, fungsi SEQUENCE akan mengembalikan array vertikal sepanjang parameter yang kita input.
Rumus berikut akan menghasilkan daftar angka satu sampai lima secara berurut dari atas ke bawah.
=SEQUENCE(5)
Cara Membuat Nomor Urut ke Samping di Excel
Bila array yang diinginkan terentang dari kiri ke kanan, berikan nilai 1 bagi rows dan nilai sebanyak kolom yang diinginkan bagi columns.
Rumus di bawah akan membuat nomor urut dari kiri ke kanan sebanyak satu row dan tiga kolom.
=SEQUENCE(1; 3)
Rumus SEQUENCE Excel: Nomor Urut Tabel
Dua contoh sebelumnya kita membuat nomor urut ke bawah dan ke samping.
SEQUENCE memungkinkan kita menciptakan nomor urut dalam bentuk tabel dengan beberapa kolom dan baris. Caranya adalah dengan memberikan nilai lebih dari satu untuk rows dan columns.
Rumus di bawah ini akan membuat tabel dengan tiga baris dan tiga kolom. Nomor urut akan terjabar dari kiri ke kanan lalu ke bawah.
=SEQUENCE(3; 3)
Rumus SEQUENCE: Nomor Urut Mulai Dari Angka Tertentu
Sementara itu, untuk membuat array nomor urut yang dimulai dari angka tertentu, tuliskan nilai yang diinginkan bagi parameter start.
Rumus berikut akan membuat daftar angka dalam tabel tiga kali tiga yang dimulai dari angka sebelas.
=SEQUENCE(3; 3; 11)
Selain itu, nilai awal juga dapat dimulai dari angka negatif.
=SEQUENCE(3; 3; -9)
Rumus SEQUENCE: Membuat Pola Angka dengan Interval
Setiap angka di dalam array yang dihasilkan SEQUENCE tidak harus berurutan dengan selisih satu. Kita dapat menentukan interval yang berbeda.
Rumus di bawah akan membuat daftar yang terdiri dari lima baris dan tiga kolom. Daftar dimulai dari nol dengan selisih sepuluh untuk tiap angka. SEQUENCE akan menambahkan angka sepuluh ini ke angka pertama untuk mendapatkan kedua, kedua untuk ketiga, dan seterusnya.
=SEQUENCE(5; 3; 0; 10)
Dengan cara yang sama, kita juga dapat menggunakan angka negatif untuk membuat urutan mundur.
=SEQUENCE(5; 3; 70; -10)
Rumus SEQUENCE Excel: Urutan Nomor dan Huruf
Semua nilai di Excel bisa digabungkan satu sama lain dengan operator penggabungan atau fungsi CONCAT, demikian pula hasil SEQUENCE.
="Barang "&SEQUENCE(7)
Rumus di atas akan membuat daftar yang terdiri dari tujuh baris dengan nilai-nilai Barang 1 sampai Barang 7.
Dengan menggunakan referensi cell, rumus menjadi:
=B1&" "&SEQUENCE(B2)
Rumus SEQUENCE: Urutan Tanggal di Excel
Fungsi SEQUENCE juga dapat digabungkan dengan fungsi DATE untuk membuat urutan tanggal.
Potongan rumus SEQUENCE(12; 1; 1) di bawah akan mengembalikan array vertikal dengan angka 1 sampai 12. Angka-angka ini akan menjadi parameter bulan bagi fungsi DATE. Secara keseluruhan, rumus akan menghasilkan dua belas tanggal satu untuk setiap bulan di 2024.
=DATE(2024; SEQUENCE(12; 1; 1); 1)
Rumus SEQUENCE dan DATE datang dengan beragam kombinasi.
Rumus berikut akan menghasilkan urutan sepuluh tanggal yang dimulai dari 1 Januari 2024, di mana setiap tanggal berselisih tujuh hari.
=SEQUENCE(10; ; DATE(2024; 1; 1); 7)
Rumus SEQUENCE dan COUNTA
Teman-teman punya data dan ingin memberikan nomor untuk setiap baris (atau kolom) secara otomatis.
Misalkan table terdiri dari lima baris, cara termudah adalah menggunakan rumus berikut
=SEQUENCE(5)
Tapi, misalkan data bertambah, baris keenam dan berikutnya tidak punya nomor.
Agar nomor bertambah secara otomatis, gunakan SEQUENCE yang dikombinasikan dengan COUNT atau COUNTA.
=SEQUENCE(COUNTA(B:B))
COUNTA(B:B) akan melihat dan menghitung semua baris pada kolom B yang memiliki nilai, terlepas dari tipe data yang dimiliki setiap nilai. SEQUENCE kemudian akan membentuk array sebanyak hasil COUNTA.
Berhubung COUNTA juga akan menghitung kepala baris pada kolom B, nomor akan selalu kelebihan satu. Karenanya, teman-teman bisa modifikasi rumus dengan mengurangi hasil COUNTA dengan satu.
=SEQUENCE(COUNTA(B:B)-1)
Rumus SEQUENCE Excel Tidak Bekerja
Fungsi SEQUENCE Tidak Ada di Excel
Rumus SEQUENCE tidak muncul atau tidak ada di Excel karena fungsi ini hanya ada di Excel 365, Excel web, dan Excel 2021 ke atas.
Bila teman-teman pengguna Excel selain versi-versi tersebut dan tidak berencana pindah, coba gunakan Excel web. Gratis.
Bila dipaksakan dengan menuliskan langsung, pesan error #NAME! akan tampil.
Pesan Error #SPILL!
Pesan ini terjadi karena ada cell terisi ke mana hasil SEQUENCE tertumpah.
Cell terisi ini, dan kondisi lain yang serupa, disebut sebagai obstructing cell. Hapus cell-cell semacam ini untuk menghindari #SPILL!.
Pesan Error #VALUE!
#VALUE! umumnya berhubungan dengan parameter.
Dalam SEQUENCE, pesan ini terjadi saat kita memberikan nilai yang tidak sesuai, seperti nilai negatif untuk rows atau columns.