Cara Menggunakan Fungsi Logika Excel: AND, OR, XOR, dan NOT

Fungsi logika—AND, OR, XOR, dan NOT—merupakan tulang punggung pengambilan keputusan. Fungsi-fungsi ini memungkinkan analisa kondisional dan validasi data di Excel. Dengan keempat fungsi ini, pengguna dapat mengekspresikan kriteria: baik untuk merancang model keuangan, melacak inventaris, atau membangun dashboard.

Artikel ini akan memandu teman-teman melalui dasar-dasar setiap fungsi, praktik terbaik, contoh praktis, dan solusi pemecahan masalah.

Unduh file di bawah untuk memahami setiap screenshot di artikel ini dengan lebih baik.

File: fungsi-and-or-xor-not-excel.xlsx.

Daftar Isi

Pengertian Fungsi Logika AND, OR, XOR, dan NOT di Excel

Fungsi logika di Excel mengevaluasi satu atau lebih kondisi logika dan mengembalikan nilai TRUE atau FALSE.

Fungsi AND: Mengembalikan TRUE jika semua kondisi bernilai TRUE. Jika tidak, AND mengembalikan FALSE.
```
Sintaks
AND(logical1; [logical2]; ...)
```
Fungsi OR: Mengembalikan TRUE jika paling tidak satu kondisi bernilai TRUE. Jika tidak, mengembalikan FALSE.
```
Sintaks
OR(logical1; [logical2]; ...)
```
Fungsi XOR: Mengembalikkan TRUE bila salah satu dari dua kondisi bernilai berbeda. Jika sama—TRUE dan TRUE atau FALSE dan FALSE—rumus akan mengembalikan FALSE.
```
Sintaks
XOR(logical1; [logical2];…)
```
Fungsi NOT: Membalikan TRUE menjadi FALSE dan sebaliknya.
```
Sintaks
NOT(logical)
```

Berikut keterangan parameter setiap sintaks:

logical, logical1 (wajib): Nilai atau pernyataan yang dapat dievaluasi sebagai nilai logika TRUE atau FALSE.
logical2, logical3, dan seterusnya (opsional): nilai atau pernyataan logika tambahan.

Kapan dan Bagaimana Menggunakan Fungsi Logika di Excel

Secara umum, fungsi-fungsi logika digunakan dalam rumus yang mengevaluasi kondisi untuk mengambil keputusan seperti IF, validasi data, dan pemformatan kondisional.

AND: Gunakan AND ketika kita perlu memastikan bahwa semua kriteria yang ditentukan terpenuhi sebelum suatu tindakan diambil. Contoh: Semua persyaratan pinjaman harus dipenuhi sebelum bank mencairkan dana ke rekening pemohon.
OR: Gunakan OR ketika ingin melakukan tindakan tertentu di mana paling tidak satu dari beberapa kondisi terpenuhi. Contoh: Stok ulang dilakukan bila persediaan produk menipis atau mendekati kadaluwarsa.
XOR: Berguna untuk skenario di mana hanya satu dari dua kondisi terpenuhi. Contoh: Wilayah penjualan Jakarta Timur ditangani oleh Team A atau Team B tapi tidak keduanya, untuk menghindari konflik antara tim penjualan.
NOT: Gunakan untuk membalikkan suatu kondisi. Contoh: Karyawan yang tidak mencapai minimal penjualan tidak mendapatkan bonus.

Tips Menggunakan Rumus Logika Excel

Susun argumen logika dengan jelas.
Gabungkan fungsi logika bersarang untuk kondisi yang lebih rumit.
Hindari fungsi logika bersarang terlalu dalam karena sulit dibaca.
Gunakan tanda kurung untuk memperjelas urutan evaluasi untuk rumus bersarang.
Uji rumus dengan berbagai contoh data (termasuk data kosong, error, teks ambigu) untuk memastikan akurasi.
Jangan gunakan nilai non-logika sebagai argumen, kecuali jika nilai tersebut merupakan bagian dari evaluasi logika.
Rumus di bawah ini tidak valid:
```
=NOT("amir")
```
Rumus berikut valid:
```
=NOT("amir"<>"syarifudin")
```
Pertimbangkan kemungkinan rentang data memiliki cell kosong, nilai error, atau nilai lain yang tidak diharapkan.
Gunakan ISBLANK, ISNUMBER, atau ISTEXT untuk validasi tambahan.

Contoh Penggunaan Rumus AND, OR, XOR, dan NOT di Excel

Rumus AND Excel: Semua Kondisi Harus Benar

Rumus berikut berisi kriteria pemberian bonus. Bonus diberikan bagi karyawan dengan masa kerja lebih dari 12 bulan (B5>$B$1) dan penjualan di atas 25 unit (C5>$B$2).

=AND(B5>$B$1; C5>$B$2)

Perhatikan rumus mengembalikan TRUE hanya saat kedua kriteria terpenuhi.

Tips: Contoh AND populer lainnya adalah mencari nilai yang berada di antara dua nilai lainnya. Contoh:

Menyaring tanggal-tanggal dari 15 Februari 2021 sampai 21 Mei 2021.
```
=AND(A2>=DATE(2021; 2; 15); A2<=DATE(2021; 5; 21))
```
Menyaring penjualan di atas 100 dan di bawah 300 unit.
```
=AND(A2>100; A2<300)
```

Rumus OR Excel: Salah Satu Kondisi Benar

Rumus di bawah memberikan bonus untuk karyawan dengan masa kerja lebih dari 12 bulan atau mencapai target penjualan di atas 25 unit.

=OR(B5>$B$1; C5>$B$2)

Perhatikan rumus mengembalikan TRUE saat minimal salah satu kriteria terpenuhi.

Rumus XOR Excel: Satu Benar, Satu Salah

Rumus di bawah memberikan potongan harga bagi pelanggan yang belanja di atas Rp 250.000 atau memiliki keanggotaan di toko bersangkutan, tapi tidak keduanya.

=XOR(B4>$B$1; C4="Ya")

Perhatikan rumus mengembalikan FALSE jika pelanggan belanja di atas Rp 250.000 dan adalah anggota.

Rumus NOT Excel: Membalik Nilai TRUE/FALSE

Rumus berikut memberikan poin bagi pelanggan yang memiliki keanggotaan aktif pada toko bersangkutan.

=NOT(B2="Tidak")

Menggabungkan Fungsi Logika di Dalam Rumus Bersarang

Rumus berikut melakukan evaluasi pemberian tunjangan perjalanan. Kriterianya adalah:

Lama perjalanan di atas 2 hari, dan
Berlaku bagi staf Marketing atau Sales

=AND(C2>2; OR(B2="Marketing"; B2="Sales"))

Conditional Formatting dengan Fungsi Logika Excel

Dengan menggabungkan fungsi-fungsi logika dengan conditional formatting, kita dapat menandai cell-cell yang yang sesuai dengan kriteria logika yang diberikan.

Rumus menandai staf dengan penjualan di atas 25 dan masa kerja di atas 12 bulan.

=AND(B5>$B$1; C5>$B$2)

Menggunakan Rumus FILTER dengan Logika And di Excel

Selain fungsi AND, perkalian juga dapat digunakan untuk menciptakan kondisi And. Pada proses perkalian, semua nilai harus 1 agar hasil bernilai 1 (TRUE). Satu saja bernilai 0, maka hasil perkalian akan 0 (FALSE).

Rumus berikut menyaring data bagi staff dengan masa kerja di atas 12 bulan dan penjualan di atas 25 unit.

=FILTER(A5:A9; (B5:B9>B1)*(C5:C9>B2))

Tips: Untuk menggunakan kondisi Or, gunakan penjumlahan.

Mengubah TRUE/FALSE Menjadi “Ya” atau “Tidak”

Sejauh ini, kita hanya menampilkan nilai TRUE atau FALSE sebagai hasil evaluasi. Gunakan fungsi IF atau fungsi sejenis lainnya untuk mengubah nilai logika menjadi nilai yang lebih mudah dipahami pengguna biasa.

Rumus berikut mengganti TRUE menjadi Ya dan FALSE menjadi Tidak.

=IF(AND(B5>$B$1; C5>$B$2); "Ya"; "Tidak")

Contoh Rumus Bersarang dengan AND, OR, XOR, dan NOT

Rumus berikut melakukan evaluasi terhadap kinerja perusahaan.

=AND(B2 > B3; OR(B4 > B5; B6 < B7);  XOR(B8 >= B9; B10 <= B11); NOT(B12 > B13))

B2 > B3: Penjualan di atas target, dan
OR(B4 > B5; B6 < B7): Biaya pemasaran terlalu tinggi atau inventori di bawah batas minimum, dan
XOR(B8 >= B9; B10 <= B11): Antara prospek mencapai target atau keluhan pelanggan sama atau di bawah batas minimum, dan
NOT(B12 > B13): Retur tidak melebihi batas yang ditetapkan

Penyebab dan Solusi Kesalahan pada Fungsi Logika Excel

Kesalahan	Penyebab	Solusi
Kesalahan #VALUE!	Argumen bukan ekspresi logika. Contoh: `=AND("amir")`	Pastikan argumen tersebut merupakan ekspresi logika atau menggunakan perbandingan eksplisit. Contoh: `=AND("amir"="syarifudin")`
Cell kosong	Evaluasi gagal	Gunakan ISBLANK atau nilai default sebagai pengganti cell kosong.
Hasil salah karena prioritas operator.	Tidak menggunakan tanda kurung dengan benar saat membuat rumus logika bersarang.	Pahami prioritas logika. Gunakan tanda kurung untuk mengendalikan urutan evaluasi.
Perilaku tak terduga untuk entri teks.	Uji logika mengembalikan TRUE/FALSE hanya jika nilai sama persis.	Periksa apakah teks sungguh ada atau memiliki karakter tidak terlihat

Kesimpulan

Fungsi logika—AND, OR, XOR, dan NOT—adalah alat penting untuk membangun kontrol dan kecerdasan di dalam spreadsheet. Dengan menguasai operator-operator ini, kita dapat membangun sistem evaluasi yang mencerminkan realitas bisnis, menyaring data dengan presisi, dan menyederhanakan kompleksitas..

Gunakan logika dengan struktur yang jelas, data yang bersih, dan tujuan yang terdefinisi.