Menggabungkan teks di Excel bukan hanya soal menyusun kata, tetapi bagaimana menyajikan data secara efisien dan profesional. Fungsi TEXTJOIN adalah salah satu cara paling fleksibel untuk menggabungkan teks dari beberapa cell, range, atau array—dengan kendali penuh atas pemisah serta penanganan cell kosong.
Artikel ini membahas TEXTJOIN, sintaks, kapan menggunakannya, contoh-contoh praktis, serta tips penting agar hasilnya tetap rapi dan sesuai kebutuhan.
File: fungsi-textjoin-excel.xlsx.
Apa itu Fungsi TEXTJOIN di Excel?
Fungsi TEXTJOIN adalah fungsi Excel yang menggabungkan teks dari beberapa sumber menjadi satu string, dengan pemisah yang dapat ditentukan dan opsi untuk mengabaikan cell kosong.
Sintaks TEXTJOIN(delimiter; ignore_empty; text1; [text2]; …)
Parameter:
- delimiter (wajib): Karakter pemisah setiap komponen teks, misalnya koma, spasi, atau line break.
- ignore_empty (wajib): Nilai boolean untuk menentukan apakah cell kosong diikutsertakan di dalam hasil akhir atau tidak.
- TRUE: tidak disertakan.
- FALSE: disertakan.
- text1 (wajib); text2, text3, dan seterusnya (opsional): Teks, range, atau array yang ingin digabungkan.
Kapan Menggunakan TEXTJOIN?
- Membuat daftar email atau mailing list
- Menggabungkan komponen alamat menjadi satu atau beberapa baris
- Merapikan data hasil impor yang terpecah
- Membuat label dinamis untuk dashboard atau laporan
- Menggabungkan tag, keyword, atau kategori
- Menyusun kalimat otomatis dari data.
Hal Penting Mengenai TEXTJOIN
- Gunakan pemisah yang umum dikenal, seperti koma untuk daftar, spasi untuk kalimat, dan seterusnya.
- TEXTJOIN dapat menggabungkan hingga 32.767 karakter.
- Jika ignore_empty disetel ke TRUE, cell kosong akan dilewati—menjadikan hasil lebih rapi.
- TEXTJOIN dapat digabungkan dengan fungsi-fungsi lain.
- Untuk hasil yang lebih konsisten, gunakan rumus CHAR(10) untuk line break dan CHAR(32) untuk spasi.
- TEXTJOIN tersedia di Excel 2016 ke atas, Excel Web, dan Excel 365.
Cara Menggunakan Rumus TEXTJOIN di EXCEL
Menggabungkan Teks
Rumus menggabungkan nama Made, Fajar, dan Kartika menjadi satu teks. Setiap nama dipisahkan oleh tanda koma.
=TEXTJOIN(", "; TRUE; "Made"; "Fajar"; "Kartika")
Menggabungkan Nama Depan dan Nama Belakang
Rumus menggabungkan nama depan dan nama belakang dengan spasi.
=TEXTJOIN(" "; TRUE; B1:B2)
Membuat Mailing List
Rumus di bawah membuat daftar email atau mailing list dalam satu baris teks.
=TEXTJOIN(", "; TRUE; A2:A4)
Menggabungkan Teks dengan Kriteria
Rumus menyaring hanya penjualan di atas Rp 2.500.000 dengan fungsi IF. Hasilnya digabungkan dengan TEXTJOIN.
=TEXTJOIN(", "; TRUE; IF(B2:C6>2500000; A2:A6; ""))Pengguna Excel 2019 ke atas atau Excel 365 dapat mengganti IF dengan FILTER agar rumus lebih sederhana dan mudah dibaca.
=TEXTJOIN(", "; TRUE; FILTER(A2:A6; B2:B6>2500000))
Menggabungkan Data Unik
Rumus menyaring duplikasi nama di dalam data dan menggabungkan hasilnya dalam satu baris teks.
=TEXTJOIN(", "; TRUE; UNIQUE(A2:A11))
Membuat Nomor Invoice Secara Otomatis
Rumus berikut menggabungkan imbuhan INV, tahun transaksi, dan nomor urut transaksi sebagai nomor invoice.
=TEXTJOIN("-"; TRUE; ; "INV"; A2; TEXT(B2; "000"))
Membuat Kalimat dari Data
Rumus berikut menggabungkan data dengan teks siap pakai untuk menciptakan kalimat. Pada kelanjutannya, kita dapat menggunakan kalimat ini di dashboard atau laporan.
=TEXTJOIN(" "; TRUE; $E$3; TEXT(TODAY(); "dd MMMM yyyy")&","; A2; $E$4; B2; $E$5; C2&".")
Menggabungkan Alamat di Excel
Rumus menggabungkan setiap komponen alamat menjadi satu alamat lengkap dalam satu baris.
=TEXTJOIN(", "; TRUE; B1:B6)Jika satu baris alamat terlalu panjang untuk dicetak di label, gunakan rumus berikut.
Setiap potongan alamat memiliki pemisah sendiri, yaitu koma, spasi, dan line break (pindah baris). Spasi diwakili oleh rumus =CHAR(32) dan line break oleh =CHAR(10) untuk konsistensi.
=TEXTJOIN(C2:C7; TRUE; B2:B7)
Rumus TEXTJOIN Excel Tidak Bekerja atau Hasil Tidak Sesuai
- Error #VALUE!: Terjadi karena:
- Total panjang teks lebih dari 32.767 karakter.
- delimiter berada pada cell yang mengandung error #VALUE!.
- Rumus menggunakan pemisah yang tidak valid.
- Error #NAME?: Terjadi karena
- Terjadi ketika versi Excel yang digunakan tidak memiliki fungsi TEXTJOIN yang menyebabkan fungsi tidak muncul saat diketik.
- Teks hardcode tidak menggunakan petik ganda.
- Pemisah berlebih: Terjadi saat TEXTJOIN mengolah cell kosong dan ignore_empty bernilai FALSE.
- Penggunaan angka, tanggal, dan waktu secara langsung (tanpa diformat) dapat mengakibatkan hasil tidak sesuai keinginan. Gunakan fungsi TEXT untuk membantu mengubah ketiganya menjadi teks.
Perbedaan TEXTJOIN, CONCATENATE, dan CONCAT
| Fitur | CONCATENATE | CONCAT | TEXTJOIN |
|---|---|---|---|
| Kegunaan | Menggabungkan beberapa teks | Menggabungkan beberapa teks | Menggabungkan beberapa teks dengan pemisah |
| Pemisah | Tidak (harus manual) | Tidak (harus manual) | Ada |
| Penanganan Cell Kosong | Tidak (cell kosong diikutkan) | Tidak (cell kosong diikutkan) | Ada opsi mengikutkan cell kosong |
| Dukungan Array | Tidak | Ya | Ya |
| Versi Excel | Sebelum 2016 | 2016 ke atas | 2016 ke atas |
| Penggunaan | Mendukung rumus jadul dari Excel sebelum 2016 | Penggabungan teks sederhana | Penggabungan lebih kompleks dengan pengaturan pemisah |
Kesimpulan
Fungsi TEXTJOIN di Excel adalah alat yang sangat berguna untuk menggabungkan teks secara efisien dan fleksibel. Dengan kemampuan mengatur pemisah, mengabaikan cell kosong, dan mendukung array dinamis, TEXTJOIN menjadi pilihan utama untuk menyusun data teks yang rapi dan siap digunakan.
Baik untuk membuat mailing list, label alamat, atau kalimat otomatis dalam laporan, TEXTJOIN mempercepat pekerjaan dan meningkatkan kualitas presentasi data.