Fungsi IF dalam Excel adalah salah satu alat yang paling sering digunakan untuk menganalisis data. Namun, dalam situasi di mana pengambilan keputusan memerlukan lebih dari satu kondisi, kita membutuhkan teknik yang disebut fungsi IF bertingkat. Teknik ini memungkinkan pembuatan perhitungan yang kompleks dan fleksibel dalam satu rumus.
Artikel ini membahas cara menggunakan fungsi IF bertingkat, termasuk contoh-contoh praktis untuk mempermudah penerapannya.
File: hasil-nested-if-excel.xlsx.
Apa Itu Fungsi IF Bertingkat di Excel?
Fungsi IF bertingkat, atau dikenal juga sebagai IF bersarang atau nested IF, adalah saat sebuah fungsi IF memiliki fungsi IF lain di dalamnya. Teknik ini digunakan untuk mengakomodasi beberapa kondisi dalam satu rumus.
Sintaks Dasar Fungsi IF:
IF(logical_test; value_if_true; [value_if_false])
Sintaks Fungsi IF Bertingkat:
Fungsi IF bertingkat mengganti salah satu parameter (atau lebih) dengan fungsi IF lain, contohnya:
- Posisi value_if_true:
IF(logical_test; IF(logical_test_2; value_if_true_2; [value_if_false_2]); [value_if_false])
- Posisi value_if_false:
IF(logical_test; value_if_true; IF(logical_test_2; value_if_true_2; [value_if_false_2]))
Fungsi IF yang berada di atas IF tersarang disebut IF induk. IF tersarang dapat memiliki fungsi IF lain di dalamnya.
Excel membatasi maksimal 64 fungsi IF dalam satu rumus, tetapi rumus yang lebih sederhana lebih baik untuk pemeliharaan dan debug. Pertimbangkan alternatif rumus jika memungkinkan.
Cara Menggunakan Fungsi IF Bertingkat
Pada demo ini, rumus akan memberikan nama sesuai dengan angka pada baris yang sesuai:
- 1: Satu.
- 2: Dua.
- 3: Tiga.
Berikut langkah-langkahnya:
- Ketikkan
=IF(A2=1; "Satu";. - Ketikkan fungsi IF baru untuk mengakomodasi evaluasi 2 dan 3:
IF(A2=2; "Dua"; "Tiga"). - Ketikkan
)untuk menutup fungsi IF induk. - Tekan Enter.
Rumus secara keseluruhan menjadi:
=IF(A2=1; "Satu"; IF(A2=2; "Dua"; "Tiga"))Rumus IF tersarang menggantikan posisi value_if_false.
Rumus IF Beberapa Tingkat (Tiga Kriteria atau Lebih)
Manajemen ingin memberikan status berdasarkan penjualan bulanan:
- A: Di atas 15.000.000
- B: Di atas 10.000.000
- C: Di atas 5.000.000
- D: Sampai 5.000.000
- E: Nol
Rumus:
=IF(B2>15000000; "A"; IF(B2>10000000; "B"; IF(B2>5000000; "C"; IF(B2>0; "D"; "E"))))
Untuk memahami rumus, perhatikan diagram berikut.
Prioritas Kondisi di Fungsi IF Bertingkat
Penting untuk memperhatikan urutan logika dalam rumus. Jika tidak, kondisi yang ditempatkan lebih awal akan dievaluasi terlebih dahulu dan dapat mengabaikan kondisi lain.
Perhatikan perbedaan antara dua rumus berikut:
Rumus 1:
=IF(B2>15000000; "A"; IF(B2>10000000; "B"; IF(B2>5000000; "C"; IF(B2>0; "D"; "E"))))Rumus 2:
=IF(B2=0; "E"; IF(B2>0; "D"; IF(B2>5000000; "C"; IF(B2>10000000; "B"; "A"))))Penempatan prioritas yang salah dapat menghasilkan perhitungan yang tidak sesuai harapan.
Menghitung Komisi Penjualan di Excel
Manajemen sedang menghitung komisi penjualan. Perhitungan dilakukan berdasarkan:
- 5%: di atas 15.000.000
- 4%: di atas 10.000.000
- 3%: di atas 5.000.000
- 2%: sampai 5.000.000
- 0%: Nol
Rumus:
=IF(B2>15000000; 5%; IF(B2>10000000; 4%; IF(B2>5000000; 3%; IF(B2>0; 2%; 0%))))*B2
Menggabungkan Fungsi IF Bertingkat dengan VLOOKUP
Manajemen memutuskan untuk memberikan bonus komisi pada besaran tertentu.
- Di atas 750.000: 10%.
- Di atas 250.000: 5%.
- Selain itu: 0%.
Untuk mengurangi kerumitan atau keharusan mengubah rumus saat persentase bonus berubah, gunakan VLOOKUP.
=IF(C2>750000; VLOOKUP("A"; $F$2:$G$4; 2; FALSE); IF(C2>400000; VLOOKUP("B"; $F$2:$G$4; 2; FALSE); 0))*C2
Kesimpulan
Fungsi IF bertingkat memberikan fleksibilitas dalam pengolahan data, tetapi penggunaannya harus direncanakan dengan baik. Pastikan untuk mempertimbangkan struktur logika dan mempertahankan kesederhanaan agar hasil yang diinginkan tercapai.