Rumus FIND & FINDB Excel: Mencari Posisi Teks

Saat bekerja dengan data Excel, seringkali kita perlu menemukan posisi karakter atau kata tertentu dalam sebuah teks—misalnya, memisahkan nama domain dari email atau mengambil bagian tertentu dari teks. Fungsi FIND dan FINDB adalah cara tepat untuk masalah ini.

File:fungsi-find-findb-excel.xlsx.

Daftar Isi

Apa Itu Fungsi FIND, FINDB di Excel?

Fungsi FIND dan FINDB adalah fungsi-fungsi yang mengembalikan posisi teks di dalam teks lain.

FIND: Mengembalikan posisi suatu teks di dalam teks lain, di mana setiap karakter memiliki besaran 1 byte. Cocok untuk teks biasa seperti bahasa Indonesia atau Inggris.
FINDB: Mengembalikan posisi byte dan bukan karakter. Fungsi ini digunakan jika setiap karakter memiliki ukuran lebih dari 1 byte, seperti Jepang, Cina, atau Korea.
Pada Excel dengan pengaturan bahasa seperti Indonesia atau Inggris, FINDB akan mengembalikan nilai yang sama dengan FIND.

Sintaks

FIND(find_text; within_text; [start_num])

FINDB(find_text; within_text; [start_num])

Parameter:

find_text (wajib): Teks yang ingin dicari.
within_text (wajib): Teks yang mengandung teks (find_text) yang ingin dicari.
start_num (opsional): Posisi awal di within_text di mana pencarian akan dilakukan. Nilai default adalah 1.

Hal Penting Mengenai FIND, FINDB

FIND adalah case sensitive dan tidak menerima karakter wildcard. Excel dan EXCEL dianggap berbeda.
Untuk pencarian case insensitive atau menggunakan wildcard, gunakan fungsi SEARCH.
Jika find_text adalah teks kosong (“”), rumus akan mengembalikan 1.
FIND akan mengembalikan #VALUE! jika:
- Teks yang dicari tidak ditemukan.
- start_num lebih kecil dari 1.
- start_num lebih besar dari panjang within_text.
Gunakan start_num untuk:
- Melewati badan teks yang tidak diinginkan.
- Mencari teks ke-2, ke-3, dan seterusnya.

Cara Menggunakan Rumus FIND, FINDB Excel

Rumus Dasar FIND

Rumus di bawah mengembalikan posisi a pertama di teks Surya Adibrata, yaitu 5.
```
=FIND("a"; B1)
```
Rumus mengembalikan posisi a dengan pencarian yang dimulai dari karakter ke-6 di dalam teks Surya Adibrata.
```
=FIND("a"; B1; 6)
```

FIND adalah case sensitive. Perhatikan rumus kedua. Rumus mengembalikan 12 dan tidak 7, yang merupakan posisi karakter A.

Rumus Dasar FINDB

Rumus di bawah mengembalikan posisi byte karakter 办 di dalam teks 上海办公室, yaitu 5.

Rumus mengembalikan 5 karena setiap karakter memiliki nilai 2 byte, alih-alih 1 seperti alfabet latin.

=FINDB("办"; B1)

Jika Excel memiliki pengaturan DBCS (Double-Byte Character Settings), seperti Jepang, Cina, atau Korea, FINDB akan mengembalikan posisi byte. Jika Excel memiliki pengaturan non DBCS, seperti Bahasa Indonesia atau Inggris, FINDB berlaku sama seperti FIND.

Mencari Kata Tertentu dari Email

Rumus berikut mencari kata Penting di dalam judul email. ISNUMBER akan mengubah angka kembalian FIND menjadi TRUE atau FALSE. IF mengubah nilai boolean menjadi Ya atau Tidak.

=IF(ISNUMBER(FIND("Penting"; A2)); "Ya"; "Tidak")

Mengambil Nama Pertama dari Nama Lengkap

Rumus berikut mengambil nama pertama dari nama lengkap dengan menggunakan kombinasi FIND dan LEFT.

=LEFT(A2; LEN(A2) - FIND(" "; A2) - 1)

Mengambil Nama Domain dari Alamat Email

Alamat email terdiri dari nama nama pengguna dan domain yang dipisahkan oleh tanda ampersan. Rumus berikut memisahkan nama domain dari keseluruhan alamat.

=MID(A2; FIND("@"; A2) + 1; LEN(A2) - FIND("@"; A2))

Mencari Spasi Kedua di Dalam Nama

Rumus berikut menggunakan konsep rumus FIND bersarang atau bertingkat untuk menemukan spasi kedua di dalam suatu teks.

Rumus seperti ini berguna untuk mengambil nama tengah atau terakhir dari suatu nama lengkap.

=FIND(" "; A2; FIND(" "; A2) + 1)

Mengambil Nama File dari Pesan Log

Rumus berikut menggunakan konsep rumus FIND bersarang lebih jauh dengan mencari nama file di dalam pesan log.

IFERROR mengantisipasi kemungkinan rumus MID tidak menemukan apa pun dengan menggantikan nilai error dengan teks kosong.

=IFERROR(MID(A2; FIND("'"; A2)+1; FIND("'"; A2; FIND("'"; A2)+1) - FIND("'"; A2) - 1); "")

Penutup

Fungsi FIND dan FINDB adalah alat powerful untuk manipulasi teks di Excel:

Mencari posisi karakter dengan presisi (case-sensitive).
Bekerja dengan multi-byte karakter (seperti bahasa Asia).
Mengombinasikan dengan fungsi lain seperti LEFT, MID, atau IF untuk otomatisasi data.