Fungsi AVERAGE Excel: Mencari Rata-rata

Artikel ini membahas cara menggunakan fungsi AVERAGE pada Excel untuk menghitung rata-rata.

Unduh file xlsx di bawah untuk melihat langsung rumus-rumus yang dijelaskan di artikel ini.

Daftar Isi

Apa Itu Rata-Rata?

Memahami cara menghitung rata-rata secara manual adalah langkah penting untuk memverifikasi hasil rumus Excel. Rata-rata diperoleh dengan membagi jumlah seluruh angka dengan banyaknya angka. Contoh:

1 angka (5): Rata-rata → 5/1=30
2 angka (35 dan 25): Rata-rata → (35+25)/2 = 30.
5 angka (5, 10, 15, 20, 25): Rata-rata → (5+10+15+20+25)/5 = 15.

Rata-rata sering disebut sebagai mean. Rumus manual yang setara di Excel:

SUM(range)/COUNT(range)

Apa Itu Fungsi AVERAGE di Excel

Fungsi AVERAGE digunakan untuk menghitung rata-rata dari sejumlah angka atau range data.

Sintaks

AVERAGE(number1; [number2; …; number255])

number1 (wajib): angka atau rentang angka yang dihitung rata-ratanya.
number2 hingga number255 (opsional): data tambahan.

Mengapa Rumus AVERAGE Tidak Berfungsi?

Jika fungsi AVERAGE tidak berfungsi, periksa:

Parameter bukan angka: Pastikan hanya angka atau range dengan angka yang digunakan. Format teks atau nilai logika (TRUE/FALSE) diabaikan.
Pesan error: Pesan seperti #DIV/0!, #VALUE!, atau #N/A akan menyebabkan rumus gagal.
Cell kosong dan angka 0 (nol): Rumus AVERAGE mengabaikan cell kosong tapi angka 0 (nol) tetap dihitung.

Cara Menggunakan Fungsi AVERAGE pada Excel

Penggunaan standar: menghitung rata-rata satu angka atau lebih.
```
=AVERAGE(5)
```
```
=AVERAGE(5; 10; 15; 20; 25)
```
Menghitung rata-rata dari satu kolom.
```
=AVERAGE(A2:A6)
```
Rumus menjumlahkan angka-angka pada kolom A (A2:A6) rentang data terkait.
Menggunakan rumus AVERAGE dari kolom yang berbeda.
Rumus AVERAGE seperti di bawah kita gunakan jika data berada pada cell atau range yang tidak berdekatan.
```
=AVERAGE(B3:B5;E3:E5)
```
Menggunakan rumus array.
```
=AVERAGE({5;10;15;20;25})
```

Rata-rata Waktu dan Persentase

Waktu dan persentase di Excel adalah angka desimal. Keduanya dapat dihitung selayaknya angka biasa.

Rata-rata waktu: Bila hasil rata-rata tidak berupa waktu, gunakan format waktu yang berlaku.
Rata-rata persentase: Bila hasil rumus tidak berupa persentase, gunakan format Percentage.

Rumus AVERAGE dengan Kriteria

Mencari rata-rata untuk data tertentu berdasarkan kriteria:

Rumus berikut menghitung rata-rata hanya penjualan oleh Evelyne.

=AVERAGE(IF(A2:A6="Evelyne"; B2:B6))

Catatan: rumus mengaplikasikan konsep dynamic array.

Untuk fungsi rata-rata dengan kriteria tanpa menggunakan IF, gunakan AVERAGEIF atau AVERAGEIFS.

Mengatasi Error #DIV/0! Rumus AVERAGE

Untuk menghindari error #DIV/0! gunakan IF. IF mengevaluasi kemungkinan banyaknya data sama dengan nol.

=IF(COUNT(B4:B8)>0; AVERAGE(B4:B8); 0)

Cara lain yang lebih praktis adalah menggunakan fungsi IFERROR.

=IFERROR(AVERAGE(B4:B8); 0)

Menghitung Nilai di Atas Rata-rata

Gunakan fungsi IF untuk membandingkan angka penjualan dengan rata-rata penjualan. Setelahnya, gunakan fungsi COUNT untuk menghitung banyaknya atau SUM untuk mencari jumlahnya.

=COUNT(IF(B2:B7>AVERAGE(B2:B7); B2:B7))

=SUM(IF(B2:B7>AVERAGE(B2:B7); B2:B7))

Menghitung Rata-rata Nilai Tertinggi atau Terendah

Kombinasikan fungsi AVERAGE dengan fungsi LARGE atau SMALL untuk mengambil rata-rata nilai-nilai terbaik atau terendah.

=AVERAGE(LARGE(B2:B7; SEQUENCE(3)))

=AVERAGE(SMALL(B2:B7; SEQUENCE(3)))

Penutup

Bila teman-teman ada pertanyaan mengenai fungsi AVERAGE atau bagaimana mengaplikasikannya pada kasus tertentu, layangkan melalui kolom komentar atau form Hubungi Kami.