Rumus di Excel tidak selalu berupa fungsi. Operasi-operasi sederhana seperti pengurangan atau menggabungkan teks tetap dapat dilakukan menggunakan operator seperti tanda minus (-) atau tanda ampersan (&).
Artikel ini membahas operator-operator di Excel serta contoh penggunaannya di dalam rumus.
Apa Itu Operator Dalam Microsoft Excel?
Operator di Excel adalah simbol atau tanda yang digunakan di dalam rumus untuk melakukan operasi tertentu.
Contoh operator adalah tanda asterisk (*) yang digunakan dalam operasi perkalian.
Jenis Operator yang Ada di Microsoft Excel
Secara keseluruhan, ada lima macam operator di Excel, yaitu:
- Operator aritmetika.
- Operator perbandingan.
- Operator penggabungan teks.
- Operator referensi.
- Operator logika.
Ada satu macam operator lagi yang mungkin tidak termasuk dalam lima di atas, tapi akan kita bahas, yaitu operator-operator unary.
Operator Aritmetika Excel
Operator aritmetika adalah operator-operator untuk melakukan perhitungan matematika sederhana, seperti penjumlahan dan perkalian.
Excel mengenal enam macam operator aritmetika.
| Operator | Keterangan | Contoh |
|---|---|---|
| + | Tanda plus atau tambah untuk penjumlahan. | =6+2 |
| – | Tanda minus atau dash untuk pengurangan. | =6-2 |
| * | Tanda asterisk untuk perkalian. | =6*2 |
| / | Tanda forward slash (atau slash saja) untuk pembagian. | =6/2 |
| % | Tanda persen untuk mengubah angka menjadi persentase. | =6*20% |
| ^ | Tanda sisipan untuk pangkat. | =6^2 |
Contoh-contoh rumus lainnya dengan operator-operator aritmetika.
=2^3*(6-2)*2+6+6/2=FALSE*FALSE=60-60*20%
Mengenai Operator Aritmetika Excel
- Hanya dapat digunakan untuk operasi yang melibatkan angka (atau bentuk angka lainnya), baik nilai langsung, referensi cell, nama cell, hasil rumus, atau array.
- Bila digunakan untuk teks, Excel akan menampilkan notifikasi error atau pesan kesalahan #NAME!.
- Bila digunakan untuk operasi yang melibatkan nilai logika, yaitu TRUE dan FALSE, Excel akan mengubah TRUE menjadi 1 dan FALSE menjadi 0.
- Tanda persen dapat digunakan sebagai entri tersendiri tanpa tanda sama dengan. Contoh: 62%.
Operator Perbandingan Excel
Operator perbandingan adalah operator yang digunakan untuk membandingkan dua nilai dan mengembalikan nilai logika TRUE atau FALSE.
Dalam Excel, operator perbandingan pada kondisi evaluasi, seperti conditional formatting atau tes logika. Beberapa fungsi Excel seperti IF, SUMIF, atau SUMPRODUCT sangat erat kaitannya dengan penggunaan operator perbandingan.
| Operator | Keterangan | Contoh |
|---|---|---|
| = | Sama dengan | =6=2 |
| > | Lebih besar | =6>2 |
| < | Kurang dari | =6<2 |
| >= | Lebih besar atau sama dengan | =6>=2 |
| <= | Lebih kecil atau sama dengan | =6<=2 |
| <> | Tidak sama dengan | =6<>2 |
Contoh penggunaan lain di dalam rumus:
=IF(6<2; "Enam lebih kecil dari dua"; "Enam lebih besar dari dua")=SUMPRODUCT(({1,2,3,4,5}>=2)*{1,2,3,4,5})
Mengenai Operator Perbandingan Excel
- Operator perbandingan dapat digunakan untuk tipe data apa pun di Excel, baik teks dan semua bentuk angka.
- Untuk teks, perbandingan bersifat case insensitive. Artinya, Excel, eXcel, dan excel akan dianggap sama.
Operator Penggabungan Teks
Operator penggabungan teks adalah operator, seperti namanya, yang digunakan untuk menggabungkan teks.
Excel hanya punya satu operator
| Operator | Keterangan | Contoh |
|---|---|---|
| & | Menggabungkan teks. | ="Enam"&" Dua" |
Contoh lain yang lebih kompleks bisa dilihat pada rumus berikut:
=RIGHT("Microsoft Excel"; 5)&"andor"Mengenai Operator Penggabungan Teks
- Operator penggabungan juga berlaku untuk angka.
- Bila menggabungkan angka atau hasil rumus berupa angka, maka hasil akhir rumus bukan lagi angka, melainkan teks.
Operator Referensi Excel
| Operator | Keterangan | Contoh |
|---|---|---|
| : | Membuat referensi yang mengikutkan semua cell yang berada di antara kedua referensi yang dinyatakan, termasuk dua referensi itu sendiri. Hasil referensi seperti ini disebut sebagai range. | =A2:J11
A2:J11 adalah range. |
| , atau ; | Tanda koma atau titik koma adalah pemisah daftar yang menggabungkan beberapa referensi menjadi satu. Penggunaan salah satunya tergantung pada sistem di mana Excel berada. Pada sistem yang menggunakan pemisah desimal titik (seperti Amerika Serikat), pemisah daftar adalah tanda koma. Pada sistem dengan pemisah desimal koma (seperti Indonesia), pemisah daftar adalah titik koma. | =SUM(A2, C2:L11) |
| spasi | Operator perpotongan yang mengambil cell-cell yang sama di antara dua referensi atau lebih. Pada contoh, hasil rumus adalah array berupa nilai-nilai di E2:H11. | =SUM(A2:H11 E2:K11) |
| # | Tanda pagar mewakili cell-cell hasil tumpahan rumus array. | =SUM(B2#)Rumus ini menjumlahkan semua nilai tumpahan pada array range bersangkutan. B2 adalah cell di mana rumus array ditulis. |
| @ | Tanda ampersan adalah operator untuk irisan implisit. | =@D1:D5Rumus di atas mengembalikan nilai pertama dari range (atau array) D1:D5.
Rumus di atas mengacu pada data di kolom Kuantitas dan Harga di dalam tabel data Penjualan, pada baris di mana rumus ditulis. |
Operator Logika Excel
Operator logika adalah operator yang menguji suatu pernyataan logika dan mengembalikan nilai logika TRUE atau FALSE.
Seperti operator perbandingan, operator logika banyak digunakan di kondisi evaluasi.
| Operator | Keterangan | Contoh |
|---|---|---|
| AND | Mengembalikan TRUE bila semua pernyataan bernilai TRUE. | =AND(6<>2; 6=2) |
| OR | Mengembalikan FALSE bila semua pernyataan bernilai FALSE. | =OR(6>2; 6<2) |
| XOR | Mengembalikan TRUE bila pernyataan-pernyataan yang ada unik satu sama lain. | =XOR(6=2; 6<>2) |
| NOT | Membalikan nilai logika yang diterima. | =NOT(6<2) |
Operator-operator logika juga dapat menerima angka dan turunannya.
Lebih lanjut mengenai operator-operator logika, silahkan baca artikel berikut.
Baca: Operator-operator logika Excel.
Operator Unary Excel
Operator unary adalah operator yang bekerja pada atau berlaku untuk suatu nilai tunggal.
Sepanjang pengetahuan kami, operator unari atau unary operators tidak termasuk dalam kategori operator mana pun. Namun, beberapa orang menganggap operator-operator ini sebagai bagian dari operator aritmetika.
| Operator | Keterangan | Contoh |
|---|---|---|
- | Konversi angka ke negatif. | =-62 |
-- | Konversi nilai logika menjadi 1 untuk TRUE atau 0 untuk FALSE atau negasi nilai negatif menjadi positif. | =--TRUE()
|
Tergantung dari bagaimana kita melihatnya, tanda tambah (+) atau persen (%) juga dapat berfungsi sebagai operator unary. Tanda tambah memastikan bahwa nilai entri adalah positif. Tanda persen mengubah angka menjadi persentase.
Tanda minus (-) untuk membuat angka negatif dapat ditulis langsung tanpa sama dengan. Sementara itu, operator unary dua tanda minus (--) harus berada di dalam suatu rumus.
=SUMPRODUCT(--({1,2,3,4,5}>=2), {1,2,3,4,5})
Mengenai Operator Unary Excel
- Operator-operator unary hanya berlaku untuk angka atau turunan angka, tidak untuk teks.
- Bila diterapkan pada teks, Excel akan mengembalikan pesan kesalahan #VALUE!.
Prioritas Operasi dan Urutan Operator di Excel
Prioritas Operator
Prioritas operator adalah operasi oleh operator mana yang harus didahulukan saat dua atau lebih operator berada dalam rumus yang sama.
| Operator | Keterangan |
|---|---|
| : (titik dua) (spasi) , (koma) atau (;) titik koma | Operator-operator referensi |
| () | Tanda kurung |
| – | Negasi (Contoh: -3) |
| % | Persen |
| ^ | Pangkat |
| * dan / | Perkalian dan pembagian |
| + dan – | Penjumlahan dan pengurangan |
| & | Menggabungkan dua teks |
| = < > <= >= <> | Perbandingan |
Urutan Operator
Pada tabel di atas, beberapa operator memiliki prioritas yang sama.
Saat operator-operator dengan prioritas sama berada bersebelahan pada rumus yang sama, operasi operator yang berada di kiri dilakukan terlebih dahulu.
Contoh Perhitungan dengan Prioritas dan Urutan
Agar dapat memahami prioritas dan urutan lebih baik, perhatikan rumus berikut.
=((A1+3)*(SUM(A1:A5)-2)/2)^2-(B3/2*B1)+(B5/2)+B2
Teman-teman dapat mencoba menghitung sendiri rumus secara manual. Bila bingung, tabel di bawah menjabarkan perhitungan rumus secara berurutan.
| Rumus | Potongan | Hasil |
|---|---|---|
=((A1+3)*(SUM(A1:A5)-2)/2)^2-(B3/2*B1)+(B5/2)+B2 | (A1+3) | 4 |
SUM(A1:A5) | 9 | |
B3/2 | 2 | |
(B5/2) | 1 | |
=(4*(9-2)/2)^2-(2*B1)+1+B2 | (9-2) | 7 |
(2*B1) | 2 | |
=(4*7/2)^2-2+1+B2 | (4*7) | 28 |
=(28/2)^2-2+1+B2 | (28/2) | 14 |
=14^2-2+1+B2 | 14^2 | 196 |
=196-2+1+B2 | 196-2 | 194 |
=194+1+B2 | 194+1 | 195 |
=195+B2 | 195+B2 | 200 |