Fungsi IF adalah salah satu alat paling serbaguna di Excel karena memungkinkan kita membuat keputusan berdasarkan kondisi tertentu. Namun, bagaimana jika keputusan yang harus diambil melibatkan lebih dari satu kondisi? Di sinilah IF bertingkat menjadi solusi.
Artikel ini membahas konsep dasar IF bertingkat, sintak, praktik terbaik, contoh rumus dari yang sederhana hingga kompleks, serta alternatif modern seperti IFS dan SWITCH.
File: rumus-if-bertingkat-excel.xlsx
Konsep Dasar Fungsi IF Bertingkat di Excel
IF bertingkat atau IF bersarang atau nested IF adalah struktur rumus di mana satu fungsi IF disisipkan di dalam fungsi IF lainnya. Struktur ini memungkinkan kita mengevaluasi beberapa kondisi secara berurutan.
Berikut sintak dasar fungsi IF.
IF(logical_test, value_if_true, [value_if_false])
Dalam IF bertingkat, value_if_false, value_if_true, atau bahkan logical_test bisa berisi fungsi IF lain.
Excel mendukung hingga 64 tingkat IF dalam satu rumus. Namun, praktik terbaik menyarankan sebanyak-banyaknya 7 tingkat.
Visualisasi Rumus IF Bertingkat
Rumus IF berikut menempatkan IF-IF tersarang pada value_if_false.
=IF(A2="A"; "Huruf A"; IF(A2="B"; "Huruf B"; IF(A2="C"; "Huruf C"; "Lainnya")))Gambar di bawah menunjukkan bagaimana rumus IF bertingkat bekerja. Setiap tingkatan mewakili kriteria tertentu. Jika kondisi terpenuhi, IF akan menjalankan value_if_true pada tingkat tersebut. Jika tidak, alur logika akan menguji tingkatan di bawahnya.
Kapan Menggunakan Rumus IF Bertingkat?
- Kondisi berjenjang, misalnya sistem penilaian atau klasifikasi
- Jumlah kemungkinan hasil terbatas, 2 sampai 7 kemungkinan
- Validasi cepat tanpa membuat kolom atau tabel pembantu
- Fungsi seperti IFS atau SWITCH terasa berlebihan atau tidak tersedia
Tips Menulis Rumus IF Bertingkat di Excel
- Gunakan indentasi atau baris baru (Alt+Enter) di Formula Bar agar rumus mudah dibaca
- Batasi kedalaman IF sedalam-dalamnya 7 tingkat untuk menjaga keterbacaan
- Uji bertahap: Bangun rumus sedikit demi sedikit dan uji setiap bagian
- Dokumentasikan logika di cell terdekat atau gunakan Note.
- Pertimbangkan alternatif seperti IFS, SWITCH, atau CHOOSE untuk logika kompleks
- Pastikan data bersih: Hindari spasi tersembunyi atau format data yang tidak konsisten
Contoh Rumus IF Bertingkat di Excel
Sistem Penilaian (Grading System)
Rumus di bawah mengevaluasi setiap angka untuk mendapatkan nilai mutu.
Perhatikan urutan kondisi. Nilai tertinggi harus diuji lebih dulu agar hasilnya akurat. Jika nilai terendah diuji pertama kali, semua nilai di atas 60 akan mengembalikan D.
=IF(B2>=90; "A";
IF(B2>=80; "B";
IF(B2>=70; "C";
IF(B2>=60; "D";
"F"))))
Perhitungan Komisi Progresif
Rumus di bawah menghitung komisi berdasarkan nilai penjualan di B2. Persentase komisi meningkat sesuai ambang batas. Pastikan urutan kriteria dari tertinggi ke terendah.
=IF(B2>=10000000; 1,9%;
IF(B2>=7500000; 1,8%;
IF(B2>=5000000; 1,7%;
1,6%)))*B2
Validasi Data
Rumus berikut memastikan bahwa semua data telah diisi dan usia berupa angka. Cocok untuk form input sederhana.
=IF(B2=""; "Masukkan nama";
IF(C2=""; "Masukkan email";
IF(NOT(ISNUMBER(D2)); "Usia tidak valid";
"Valid")))
Evaluasi Keanggotaan Berdasarkan Lama Bergabung
Rumus berikut menentukan status keanggotaan berdasarkan lama bergabung (B2) dan status pendaftaran (C2). Rumus menggunakan AND untuk menangani kondisi gabungan.
=IF(B2>=10; "Platinum";
IF(B2>=5; "Gold";
IF(B2>=1; "Silver";
IF(AND(B2<1; C2="Ya"); "Anggota Baru";
"Bukan Anggota"))))
Evaluasi Kinerja Berdasarkan Area dan/atau Penjualan
Rumus di bawah adalah contoh sederhana performance classification rule (atau aturan klasifikasi kinerja) dan menggunakan kombinasi fungsi IF dengan operator logika AND dan OR.
Rumus menilai kinerja berdasarkan wilayah dan penjualan. AND digunakan untuk penilaian kriteria ketat, sementara OR untuk kriteria lebih longgar.
=IF(AND(B2="Timur";C2>=500); "Kinerja Tinggi";
IF(OR(B2="West";C2>=300); "Kinerja Menengah";
IF(C2<300;"Kinerja Rendah";
"Periksa Data")))
Masalah Umum Rumus IF Bertingkat dan Solusinya
| Masalah | Penyebab | Solusi |
|---|---|---|
| Kurung tidak seimbang | Lupa menutup IF | Hitung setiap kurung buka dan tutup |
| Urutan logika salah | Kondisi tidak disusun dari yang paling spesifik | Susun dari kondisi paling ketat ke paling umum |
| Kondisi tumpang tindih | Dua kondisi bisa sama-sama benar | Perjelas urutan dan batasan logika |
| Rumus sulit dibaca | Terlalu panjang dalam satu baris | Gunakan baris baru (Alt+Enter) atau kolom bantu |
| Hasil tidak sesuai | Kesalahan logika atau data | Uji setiap kondisi secara terpisah |
Alternatif Rumus IF Bertingkat
Jika IF bertingkat terasa terlalu rumit, pertimbangkan alternatif berikut:
- IFS: Menyederhanakan IF bertingkat di dalam satu rumus tanpa persarangan
- SWITCH: Cocok untuk membandingkan satu nilai terhadap banyak kemungkinan
- CHOOSE: Berguna untuk memetakan indeks ke nilai tertentu
Baca: Alternatif Rumus IF Bertingkat
Kesimpulan
Fungsi IF bertingkat adalah alat yang kuat untuk menangani logika berjenjang dalam Excel. Dengan memahami cara menyusun dan menguji rumus secara bertahap, kita dapat membuat keputusan otomatis yang kompleks tanpa kehilangan keterbacaan.
Untuk logika yang lebih kompleks, pertimbangkan alternatif seperti IFS, SWITCH, atau CHOOSE agar rumus tetap efisien dan mudah dipelihara.