Fungsi INDEX di Excel: Mengambil Nilai Berdasarkan Baris dan Kolom

Rumus pencarian adalah salah satu hal penting untuk mengambil dan mengelola informasi secara efisien di Excel. Fungsi INDEX adalah salah satu alat yang memungkinkan pengguna untuk mengambil data dari data besar dengan presisi.

Artikel ini akan membahas fungsi INDEX, tujuan pemakaian, praktik terbaik, contoh praktis, dan saran pemecahan masalah.

File: fungsi-index-excel.xlsx

Apa itu Fungsi INDEX di Excel?

Fungsi INDEX mengembalikan nilai dari sebuah cell di dalam array atau rentang tertentu, berdasarkan indeks baris dan kolom.

Berbeda dengan fungsi seperti VLOOKUP, INDEX tidak terbatas pada kolom pertama. Inilah yang membuatnya sangat fleksibel untuk lookup dinamis.

Fungsi INDEX memiliki dua bentuk sintaksis, yaitu array dan referensi.

Sintaksis: Bentuk Array

Bentuk array INDEX adalah bentuk yang paling umum digunakan.

INDEX(array; row_num; [column_num])

Di mana:

• array (wajib): Rentang cell atau konstanta array
• row_num (wajib): Nomor baris di dalam array
• column_num (opsional): nomor kolom dalam array

Sintaksis: Bentuk Referensi

Bentuk referensi adalah bentuk yang lebih jarang digunakan.

INDEX(reference; row_num; [column_num]; [area_num])

Di mana:

• reference (wajib): Referensi ke satu atau beberapa rentang cell
• row_num (wajib): Indeks baris di dalam reference
• column_num (opsional): Indeks kolom di dalam reference
• area_num (opsional): Area ke berapa yang digunakan jika reference terdiri lebih dari satu rentang

Kapan dan Mengapa Menggunakan Rumus INDEX

Gunakan INDEX ketika, tapi tidak terbatas pada:

• Posisi baris atau kolom diketahui atau bisa ditentukan dengan fungsi lain
• Membuat laporan dinamis sesuai dengan titik data
• Mengelola tabel besar di mana kemampuan VLOOKUP tidak memadai
• Digabungkan dengan MATCH atau XMATCH untuk pencarian fleksibel

Hal Penting Saat Menggunakan Rumus INDEX

• Pencarian INDEX tidak terbatas pada kolom atau baris pertama
• Gabungkan dengan MATCH atau XMATCH untuk pencarian berbasis posisi
• Gunakan rentang bernama agar rumus lebih mudah dibaca
• INDEX tidak menampilkan pesan error jika indeks salah
• Hindari penggunaan dengan rentang tidak berdekatan kecuali memahami bentuk referensi

Rumus Dasar INDEX Excel

Mengambil Nilai Berdasarkan Nomor Baris

Rumus berikut mengembalikan baris ketiga dari range A2:A6.

=INDEX(A2:A6; 3)

Di mana:

• A2:A6 (array) adalah range dari mana nilai akan dikembalikan
• 3 (row_num) adalah indeks yang menentukan lokasi baris di A2:A6

Mengambil Nilai berdasarkan Baris dan Kolom

Rumus di bawah mengembalikan nilai pada baris keempat dan kolom kedua dari rentang A2:B6.

=INDEX(A2:B6; 4; 2)

Di mana:

• A2:B6 (array) adalah range dari mana nilai akan dikembalikan
• 4 (row_num) adalah indeks yang menentukan lokasi baris di A2:B6
• 2 (column_num) adalah indeks yang menentukan lokasi kolom di A2:B6

Mengembalikan Seluruh Baris atau Kolom

Rumus di bawah mengembalikan seluruh baris kedua dari array.

=INDEX(A2:B6; 2; 0)

Di mana:

• A2:B6 (array) adalah array sumber data
• 2 (row_num) adalah indeks baris sumber data yang ingin dikembalikan
• 0 (column_num) menandakan bahwa rumus akan mengembalikan seluruh kolom array

Untuk mengembalikan seluruh baris dari suatu array, berikan nilai nol bagi row_num, seperti rumus berikut.

=INDEX(A2:B6; 0; 2)

Contoh Penggunaan Rumus INDEX Excel

Memilih Rentang Secara Fleksibel

Rumus berikut membuat referensi menggunakan operator titik dua (:) untuk menciptakan rentang di antara dua referensi cell, di mana setiap referensi berasal dari rumus INDEX. Referensi bentukan dari dua INDEX berperan sebagai argumen bagi SUM yang menjumlahkan semua angka di dalamnya.

=SUM(INDEX(B2:B6; D2):INDEX(B2:B6; E2))

Kombinasi dengan MATCH untuk Lookup Fleksibel

MATCH dapat digunakan untuk menyediakan posisi bagi INDEX. Kombinasi keduanya menciptakan rumus lookup fleksibel, ketimbang menuliskan angka indeks secara langsung (hardcoded).

Rumus di bawah mengembalikan harga Buku dengan menggunakan MATCH sebagai penunjuk lokasi baris.

=INDEX(B2:B6; MATCH(D2; A2:A6; 0))

Menggunakan Dua MATCH untuk Lookup Ganda

Rumus berikut menggunakan dua MATCH, satu sebagai indeks baris, yang lain sebagai indeks kolom. Rumus mengembalikan kuantitas penjualan Penggaris oleh Erik.

=INDEX(B2:D6; MATCH(A9; A2:A6; 0); MATCH(B9; B1:D1; 0))

Mengembalikan Ranking dengan SMALL dan LARGE

Dua rumus berikut mengembalikan nama-nama yang memiliki nilai penjualan terendah dan tertinggi menggunakan kombinasi INDEX+MATCH serta SMALL dan LARGE.

=INDEX(A2:A6; MATCH(SMALL(B2:B6; 1); B2:B6; 0))

=INDEX(A2:A6; MATCH(LARGE(B2:B6; 1); B2:B6; 0))

Mengapa Rumus INDEX Tidak Bekerja?

Kesimpulan

Fungsi INDEX adalah alat lookup fleksibel yang memungkinkan pencarian secara dinamis tanpa batasan kolom. Dengan menggabungkannya bersama MATCH atau XMATCH, kita dapat membangun sistem pencarian yang lebih kuat daripada VLOOKUP atau HLOOKUP.

Gunakan INDEX untuk laporan dinamis, analisis peringkat, atau pengelolaan data besar. Pastikan selalu memeriksa indeks baris atau kolom agar hasil sesuai harapan.