Excel membedakan angka dan teks. Jika suatu angka berformat teks, angka tersebut mungkin saja tidak bisa dijumlahkan, tidak terbaca oleh PivotTable, atau tidak bisa disaring sebagai angka.
Fungsi VALUE Excel adalah fungsi yang dapat membantu membuat data lebih dapat digunakan, sesuai formatnya.
Artikel ini membahas mengapa angka berformat teks, mengapa perlu mengubahnya menjadi angka sesungguhnya, kapan dan tips menggunakan VALUE, contoh-contoh rumus, dan masalah umum yang mungkin terjadi.
File: fungsi-value-excel.xlsx
Penyebab Umum Angka Berubah Menjadi Teks di Excel
Ada beberapa penyebab umum mengapa angka yang kita masukkan atau impor ke Excel berubah menjadi teks:
Perbedaan Format Angka dengan Pengaturan Lokal Excel
Indonesia menggunakan format:
- 1.234,56 (titik = ribuan, koma = desimal)
Sementara banyak situs menggunakan:
- 1,234.56 (koma = ribuan, titik = desimal)
Ketika angka dari Amazon atau eBay di-copy-paste-kan apa adanya ke Excel dengan pengaturan Indonesia, Excel tidak mengenali format tersebut dan menganggapnya sebagai teks.
Angka Mengandung Spasi atau Pemisah Tidak Standar
Spasi adalah karakter tidak terlihat, tetapi Excel memperlakukannya sebagai karakter.
Contoh:
- “ 12000 ” (spasi di depan/belakang)
- “12 000” (spasi ribuan)
- “12-000” (pemisah tidak standar)
Angka Mengandung Karakter Non‑Printable
Karakter non-printable adalah karakter tidak terlihat baik dalam bentuk elektronik atau pun cetak.
Contoh karakter non-printable:
- tab
- newlines
- carriage returns
Karakter-karakter ini umum ditemui saat copy paste dari PDF, sistem lama, atau ekspor dari aplikasi web.
Angka Mengandung Simbol
Simbol, seperti Rp atau $, di Excel hanya modifikasi tampilan, bukan bentuk angka sesungguhnya. Namun jika simbol tersebut menempel langsung pada teks (bukan lewat pemformatan), Excel menganggapnya sebagai teks, bukan angka..
Contoh:
- Rp 12.500
- $1,200
- IDR 15000
Angka Hasil Copy Paste dari Web
Angka hasil copy paste dari website kadang mengandung karakter HTML tersembunyi. Karakter-karakter ini sering menjadi penyebab mengapa Excel tidak mengenali angka tersebut sebagai angka.
Angka Hasil Rumus
Rumus seperti MID, LEFT, RIGHT, atau fungsi teks lainnya selalu mengembalikan teks terlepas dari karakter yang dikembalikan.
=LEFT("12ABC"; 2)Rumus di atas akan mengembalikan 12 dalam format teks dan bukan angka.
Konsekuensinya, angka tersebut tidak bisa diproses dengan rumus seperti SUM, AVERAGE, atau fitur seperti PivotTable.
Mengapa Penting Mengubah Teks Menjadi Angka?
Berikut beberapa alasan utama konversi menjadi angka penting:
- Akurasi perhitungan: Fungsi seperti SUM, AVERAGE, MAX, atau MIN hanya bekerja pada angka.
- Validasi data: Memastikan angka benar‑benar numerik sebelum analisis.
- Automasi laporan: PivotTable, grafik, dan Power Query membutuhkan angka murni.
- Mencegah error: Menghindari hasil perhitungan yang salah karena campuran teks dan angka.
Apa Itu Fungsi VALUE di Excel?
Fungsi VALUE adalah fungsi yang mengubah angka teks menjadi nilai angka yang bisa diproses Excel.
Sintaksis
VALUE(text)
- teks (wajib): Teks yang ingin diubah menjadi angka. Jika teks sudah berupa angka, fungsi ini akan mengembalikan nilai yang sama.
Contoh:
Rumus di bawah akan menghasilkan angka murni 12345, bukan teks.
=VALUE("12345")Kapan Menggunakan Fungsi VALUE?
Gunakan VALUE ketika:
- mengolah data impor dari web, PDF, POS, marketplace
- mengambil angka dari teks menggunakan fungsi teks seperti LEFT, MID, RIGHT
- membersihkan data untuk normalisasi atau sebelum analisis
- menggabungkan data dari berbagai sistem dengan format berbeda
- memproses angka dengan simbol, spasi, atau pemisah tidak standar
Tips Efektif Menggunakan Rumus VALUE
- Pastikan teks yang akan dikonversi memang dapat direpresentasikan sebagai angka. Jika ada huruf atau simbol lain, VALUE akan menghasilkan error.
- Jika bekerja dengan data besar, gunakan VALUE bersama fungsi TRIM dan CLEAN untuk menghilangkan spasi dan karakter tak kasat mata.
- Untuk kolom besar, gunakan formula array atau isi otomatis (fill handle).
- Periksa pengaturan regional Excel terkait pemisah ribuan dan desimal agar konversi berjalan lancar.
Contoh Rumus VALUE di Excel dan Kasusnya
Rumus Standar VALUE
Rumus-rumus di bawah adalah rumus-rumus standar VALUE, masing-masing mengubah teks angka, tanggal, waktu, dan desimal menjadi angka sesungguhnya.
=VALUE("1500")
=VALUE("13/05/2025")
=VALUE("11:02:06")
=VALUE("0,256")
Mengambil Nomor Urut Faktur
Nomor faktur atau invoice umum memiliki nomor urut berjalan pada periode tertentu.
Rumus di bawah mengambil nomor urut tersebut dan mengubahnya menjadi angka untuk melihat apakah ada nomor tertentu yang hilang. Umum dilakukan saat audit transaksi.
=VALUE(RIGHT(A2; 3))
Mengubah Angka Penjualan POS
Data yang diambil dari sistem POS kadang memiliki format angka di mana pemisah ribuan adalah spasi seperti “12 500”. Rumus di bawah menggunakan kombinasi dengan SUBSTITUTE untuk mengubah format angka sistem POS menjadi angka yang diterima Excel.
=VALUE(SUBSTITUTE(A2; " "; ""))
Mengambil Tanggal dari Nomor Batch
Nomor batch umum menggunakan tanggal sebagai identifikasi.
Rumus di bawah mengambil tanggal dari kode batch menggunakan MID dan VALUE agar dapat digunakan ke dalam perhitungan lain, seperti perhitungan masa simpan atau kadaluarsa.
=VALUE(MID(A2; 5; 10))
Mengubah Angka Penjualan dari Format Lokalisasi Berbeda
Jika data berasal dari sistem yang berbeda pengaturan lokalisasi dengan Excel, angka dari sistem tersebut mungkin saja tidak bisa diterima sebagai angka oleh Excel. Contoh: Rp 243.000 di sistem menggunakan pengaturan Amerika Serikat atau sebaliknya.
Rumus di bawah mengubah angka dengan lokalisasi tertentu menjadi angka murni.
=VALUE(SUBSTITUTE(SUBSTITUTE(A2; "Rp"; ""); "."; ""))
Mengambil Waktu dari Log Sistem
Timestamp log umum menyertakan waktu.
Rumus di bawah menggunakan kombinasi antara TIME, VALUE, MID, LEFT, dan RIGHT untuk mengambil komponen waktu di timestamp log dan mengubahnya menjadi waktu yang sesungguhnya.
=TIME(VALUE(LEFT(RIGHT(A2;6);2)); VALUE(MID(RIGHT(A2;6);3;2)); VALUE(RIGHT(A2;2)))
Menjumlahkan Penjualan Berdasarkan Kategori
Beberapa sistem mengubah angka menjadi format tertentu. Contoh: 000250 Unit untuk menandakan penjualan dalam unit.
Rumus berikut mengubah angka dengan format seperti di atas menjadi angka tunggal, tanpa format, menyaring berdasarkan kategori produk tertentu, lalu menjumlahkannya dengan SUMPRODUCT.
=SUMPRODUCT(VALUE(LEFT(FILTER(C2:C8; ISNUMBER(SEARCH(E2; B2:B8))); 6)))
Kesalahan Umum Rumus VALUE dan Solusinya
| Masalah | Penyebab | Solusi |
| Error #VALUE! | Teks mengandung karakter non-angka (huruf, simbol, atau spasi di tengah angka). | Bersihkan teks dengan TRIM, SUBSTITUTE, atau gunakan LEFT atau RIGHT untuk mengambil angka saja. |
| Error #VALUE! | Format pemisah desimal/ribuan tidak sesuai pengaturan regional, misal: pakai titik, seharusnya koma. | Ubah format menggunakan SUBSTITUTE, sesuaikan dengan pengaturan regional Excel. |
| Angka tetap tidak berubah | Data sudah dalam format angka, bukan teks. | VALUE akan mengembalikan angka itu sendiri, tidak perlu konversi lagi. |
| Hasil konversi waktu berupa desimal | Format cell adalah General | Ganti format ke Date |
| Hasil konversi tanggal berupa angka puluhan ribu | Format cell adalah General | Ganti format ke Time |
Kesimpulan
Fungsi VALUE di Excel adalah solusi sederhana namun sangat efektif untuk mengatasi masalah konversi teks ke angka, terutama dalam pengolahan data hasil impor, ekstraksi, atau pembersihan sebelum analisis lanjutan. Dengan memahami penyebab angka berubah menjadi teks, serta menguasai teknik dan contoh formula unik di atas, kita bisa memastikan data selalu siap pakai dan analisis berjalan akurat tanpa hambatan.